bundles/org.simantics.scl.runtime/scl/Prelude.scl

   1 import "JavaBuiltin" as Java
   2 import "StringBuilder" as StringBuilder
   3
   4 /** The following types and names are builtin *************
   5 data Boolean = True | False
   6 data Byte
   7 data Character
   8 data Short
   9 data Integer
  10 data Long
  11 data Float
  12 data Double
  13 data BooleanArray
  14 data ByteArray
  15 data CharacterArray
  16 data ShortArray
  17 data IntegerArray
  18 data LongArray
  19 data FloatArray
  20 data DoubleArray
  21 data Array a
  22 data String
  23 data a -> b
  24 data [a] = [] | [a] | [a,a] | [a,a,a] | ...
  25 data () = ()
  26 data (a,b) = (a,b)
  27 data (a,b,c) = (a,b,c)
  28 data Maybe a = Nothing | Just a
  29
  30 fail :: String -> a
  31
  32 data TypeRep = TCon String | TApply TypeRep TypeRep
  33 class Typeable a
  34 typeOf :: Typeable a => a -> Type
  35
  36 data Binding a
  37 class Serializable a
  38 binding :: Serializable a => Binding a
  39 ***********************************************************/
  40
  41 type BooleanArray = Vector Boolean
  42 type ByteArray = Vector Byte
  43 type CharacterArray = Vector Character
  44 type ShortArray = Vector Short
  45 type IntegerArray = Vector Integer
  46 type LongArray = Vector Long
  47 type FloatArray = Vector Float
  48 type DoubleArray = Vector Double
  49
  50 importJava "java.util.Arrays" where
  51     "Converts an array to a list."
  52     @JavaName asList
  53     arrayToList :: Array a -> [a]
  54
  55 importJava "java.util.List" where
  56     "Converts a list to an array."
  57     @JavaName toArray
  58     listToArray :: [a] -> Array a
  59
  60 importJava "org.simantics.scl.runtime.Coercion" where
  61     "Converts a list of doubles to a double array."
  62     toDoubleArray :: [Double] -> DoubleArray
  63     "Converts a double array to a list of doubles."
  64     fromDoubleArray :: DoubleArray -> [Double]
  65
  66 /*
  67  * Precedences and associativity of all operators defined in Prelude
  68  */
  69
  70 infixr 10 (!)
  71 infixr 9  (.)
  72 infixr 8  (^)
  73 infixl 7  (*), (/), div, mod
  74 infixl 6  (+), (-)
  75 infixl 5  (\\), (<<), (<+)
  76 infix  4  (!=), (<), (<=), (>=), (>)
  77 infixr 3  (&&), (&<&)
  78 infixr 2  (||), orElse, morelse
  79 infixr 1  (>>=), (>>), (:=), (>=>)
  80 infixr 1  ($)
  81 infixl 1  catch
  82
  83 "Creates a constant function. `const x` defines a function that always returns `x`."
  84 @inline
  85 const :: a -> b -> a
  86 const c x = c
  87
  88 """
  89 Function application. `f $ x` is equivalent with `f x`. The function has two uses.
  90 First is to remove parentheses from deeply nested expressions:
  91
  92     f (g (h x))  ==  f $ g $ h x
  93
  94 The second use is with higher order functions:
  95
  96     map ($ parameter) functions
  97 """
  98 @macro
  99 @inline
 100 ($) :: (a -> <e> b) -> a -> <e> b
 101 f $ x = f x
 102
 103 "Transforms a function taking a pair as a parameter to a function taking two values as a parameter."
 104 @inline
 105 curry :: ((a, b) -> <e> c) -> a -> b -> <e> c
 106 curry f x y =  f (x, y)
 107
 108 "Transforms a function two values as a parameter to a function taking a pair as a parameter."
 109 @inline
 110 uncurry :: (a -> b -> <e> c) -> ((a, b) -> <e> c)
 111 uncurry f (x, y) = f x y
 112
 113 "Transforms a function taking a triple as a parameter to a function taking three values as a parameter."
 114 @inline
 115 curry3 :: ((a, b, c) -> <e> d) -> a -> b -> c -> <e> d
 116 curry3 f x y z =  f (x, y, z)
 117
 118 "Transforms a function three values as a parameter to a function taking a priple as a parameter."
 119 @inline
 120 uncurry3 :: (a -> b -> c -> <e> d) -> ((a, b, c) -> <e> d)
 121 uncurry3 f (x, y, z) = f x y z
 122
 123 "Flips the parameters of a binary function."
 124 @inline
 125 flip :: (a -> b -> <e> c) -> b -> a -> <e> c
 126 flip f x y =  f y x
 127
 128 "Swaps the order of elements of a pair (2-tuple)."
 129 swap :: (a,b) -> (b,a)
 130 swap (x,y) = (y,x)
 131
 132 /// Comparison ///
 133
 134 @inline
 135 (!=) :: a -> a -> Boolean
 136 a != b = not (a == b)
 137
 138 """
 139 The class of linearly ordered types.
 140 Method `compare` must be implemented in instances.
 141 """
 142 class Ord a where
 143     """
 144     `compare x y` returns a negative number, if `x` is smaller than `y`,
 145     a positive number, if `x` is bigger than `y` and zero if they are equal.
 146     """
 147     compare :: a -> a -> Integer
 148     compare a b = if a < b then -1 else if a > b then 1 else 0
 149
 150     "Less"
 151     (<) :: a -> a -> Boolean
 152     a < b = compare a b < 0
 153     "Less or equal"
 154     (<=) :: a -> a -> Boolean
 155     a <= b = compare a b <= 0
 156     "Greater"
 157     (>) :: a -> a -> Boolean
 158     a > b = compare a b > 0
 159     "Greater or equal"
 160     (>=) :: a -> a -> Boolean
 161     a >= b = compare a b >= 0
 162
 163     "Minimum of the parameters"
 164     min :: a -> a -> a
 165     min a b = if a < b then a else b
 166     "Maximum of the parameters"
 167     max :: a -> a -> a
 168     max a b = if a > b then a else b
 169
 170 """
 171 Combines two integers such that if the first one is non-zero, it is returned, otherwise
 172 the second-one. The second parameter is not implemented, if it is not needed.
 173
 174 The function is useful for implementing efficient recursive comparison of structures,
 175 for example:
 176
 177     compare (x1,y1,z1) (x2,y2,z2) = compare x1 x2 &<& compare y1 y2 &<& compare z1 z2
 178 """
 179 @inline
 180 (&<&) :: Integer -> (<e> Integer) -> <e> Integer
 181 a &<& b = if a == 0 then b else a
 182
 183 "Maximum over a list"
 184 @inline
 185 maximum :: Ord a => [a] -> a
 186 maximum = foldl1 max
 187
 188 "Minimum over a list"
 189 @inline
 190 minimum :: Ord a => [a] -> a
 191 minimum = foldl1 min
 192
 193 "As `maximum` but compares the elements by the given projection."
 194 maximumBy :: Ord b => (a -> <e> b) -> [a] -> <e> a
 195 maximumBy f l = snd $ foldl1 maxF $ map (\x -> (f x, x)) l
 196   where
 197     maxF a b = if fst a >= fst b then a else b
 198
 199 """
 200 As `minimum` but compares the elements by the given projection.
 201 For example
 202
 203     minimumBy snd l
 204
 205 returns a pair with the smallest second component.
 206 """
 207 minimumBy :: Ord b => (a -> <e> b) -> [a] -> <e> a
 208 minimumBy f l = snd $ foldl1 minF $ map (\x -> (f x, x)) l
 209   where
 210     minF a b = if fst a <= fst b then a else b
 211
 212 /// Functions ///
 213 /*
 214 instance Functor ((->) a) where
 215     map f g x = f (g x)
 216
 217 instance Monad ((->) a) where
 218     return v x = v
 219     (m >>= f) x = f (m x) x
 220     join f x = f x x
 221
 222 instance Category (->) where
 223     id x = x
 224     @inline
 225     (f . g) x = f (g x)
 226 */
 227 instance (Additive b) => Additive (a -> <e> b) where
 228     zero x = zero
 229     (f + g) x = f x + g x
 230
 231 instance (Ring b) => Ring (a -> <e> b) where
 232     one x = one
 233     (neg f) x = neg (f x)
 234     (f - g) x = f x - g x
 235     (f * g) x = f x * g x
 236     (fromInteger c) x = fromInteger c
 237
 238 //instance Show (a -> <e> b) where
 239 //    show f = "<function>"
 240
 241 "Appends a string to the string builder."
 242 (<<) :: StringBuilder.T -> String -> <Proc> StringBuilder.T
 243 (<<) =  StringBuilder.appendString
 244
 245 """
 246 The class of types whose elements can be converted to a string representation.
 247 Method `show` or `(<+)` must be implemented.
 248 """
 249 class Show a where
 250     "Converts a value to string."
 251     show :: a -> String
 252     "Appends the string representation of the value to the string builder."
 253     (<+) :: StringBuilder.T -> a -> <Proc> StringBuilder.T
 254     """
 255     Returns the precedence of the value. It is used to determine if parenteheses
 256     are needed around the string representation of the value. The default value is 0
 257     and means that parentheses are never added.
 258     """
 259     precedence :: a -> Integer
 260
 261     "Converts a value to a string like `show` but does not put string literals in double quotes."
 262     showForPrinting :: a -> String
 263
 264     show v = runProc (StringBuilder.toString (StringBuilder.new <+ v))
 265     showForPrinting v = show v
 266     sb <+ v = StringBuilder.appendString sb (show v)
 267     precedence v = 0
 268
 269 """
 270 `Par` data type is used to control the placement of parentheses when converting values to string.
 271 Value `Par prec val` is converted to string like `val` but parentheses are put around, if the
 272 precedence of the value is greater than `prec`.
 273 """
 274 data Par a = Par Integer a
 275
 276 instance (Show a) => Show (Par a) where
 277     sb <+ (Par outerPrec v) = if prec > outerPrec
 278                                  then sb << "(" <+ v << ")"
 279                                  else sb <+ v
 280                               where prec = precedence v
 281
 282 "Type class for parsing strings to values."
 283 class Read a where
 284     "Converts a string to a required type of value."
 285     read :: String -> a
 286 """
 287 The `Additive` class is used for types that are additive monoids. The operations
 288 must satisfy the following laws (at least approximately, when implemented for
 289 floating point numbers):
 290     (a + b) + c   = a + (b + c)
 291     a + 0 = 0 + a = a
 292 """
 293 class Additive a where
 294     """
 295     Neutral element of (+), i.e,
 296
 297         x + zero == x
 298         zero + x == x
 299     """
 300     zero :: a
 301     "Adds two objects (numbers, vectors, strings, etc.) together."
 302     (+)  :: a -> a -> a
 303     """
 304     Sum of the elements:
 305
 306         sum [e1,e2,...,eN] = e1 + e2 + ... + eN
 307
 308     Implemented usually more efficiently than with repetitive
 309     application of `(+)`.
 310     """
 311     sum  :: [a] -> a
 312     sum = foldl (+) zero
 313 /*
 314 class (Additive a) => AdditiveGroup a where
 315     neg :: a -> a
 316     (-) :: a -> a -> a
 317     x - y = x + (neg y)
 318 */
 319 """
 320 The `Ring` class is used for types that are algebraic rings. The operations
 321 must satisfy the following laws (at least approximately)
 322 in addition to the laws of Additive:
 323
 324     a + b         = b + a
 325     a - b         = a + (neg b)
 326     a - a         = 0
 327     (a * b) * c   = a * (b * c)
 328     a * 1 = 1 * a = a
 329     a * (b + c)   = a * b + a * c
 330     (a + b) * c   = a * c + b * c
 331 """
 332 class (Additive a) => Ring a where
 333     """
 334     Negation. Synonym for unary `-`.
 335     """
 336     neg :: a -> a
 337     "Subtraction"
 338     (-) :: a -> a -> a
 339     "Neutral element of multiplication"
 340     one :: a
 341     "Multiplication"
 342     (*) :: a -> a -> a
 343     "Converts an integer to a desired numeric type."
 344     fromInteger :: Integer -> a
 345     x - y = x + (neg y)
 346
 347
 348 """
 349 The `OrderedRing` class combines the Ring and Ord classes. It additionally
 350 supports absolute value function.
 351 """
 352 class (Ring a, Ord a) => OrderedRing a where
 353     "Absolute value."
 354     abs :: a -> a
 355     abs x = if x < zero then neg x else x
 356     "Converts the given number to `Integer`"
 357     toInteger :: a -> Integer
 358
 359 """
 360 The `Integer` class is used for types that represent either all integers or some
 361 range of them.
 362 """
 363 class (OrderedRing a) => Integral a where
 364     "Integer division truncated toward zero."
 365     div :: a -> a -> a
 366     "Integer remainder, satisfying ``(x `div` y)*y + (x `mod` y) = x``"
 367     mod :: a -> a -> a
 368
 369 """
 370 The `Real` class is used for types that represent some approximation of real numbers.
 371 """
 372 class (OrderedRing a) => Real a where
 373     "Division"
 374     (/) :: a -> a -> a
 375     "Exponentation"
 376     (^) :: a -> a -> a
 377     "Pi (3.141592654...)"
 378     pi  :: a
 379     "Square root"
 380     sqrt :: a -> a
 381     "Exponent function"
 382     exp :: a -> a
 383     "Natural logarithm"
 384     log :: a -> a
 385     "Sine"
 386     sin :: a -> a
 387     "Cosine"
 388     cos :: a -> a
 389     "Tangent"
 390     tan :: a -> a
 391     "Inverse sine"
 392     asin :: a -> a
 393     "Inverse cosine"
 394     acos :: a -> a
 395     "Inverse tangent."
 396     atan :: a -> a
 397     "Hyperbolic sine"
 398     sinh :: a -> a
 399     "Hyperbolic cosine"
 400     cosh :: a -> a
 401     "Hyperbolic tangent"
 402     tanh :: a -> a
 403     "Inverse hyberbolic sine"
 404     asinh :: a -> a
 405     "Inverse hyberbolic cosine"
 406     acosh :: a -> a
 407     "Inverse hyberbolic tangent"
 408     atanh :: a -> a
 409     "The largest integer not greater than the given number"
 410     floor :: a -> a
 411     "The smallest integer not smaller than the given number"
 412     ceil :: a -> a
 413     round :: a -> Long
 414     """
 415     Two parameter version of `atan`. Its value is determined by the following
 416     equations when (x,y) is a unit vector:
 417
 418         x = cos (atan2 y x)
 419         y = sin (atan2 y x)
 420
 421     When x > 0,
 422
 423         atan2 y x = atan (y/x)
 424     """
 425     atan2 :: a -> a -> a
 426     "Converts a `Double` value to a desired numeric type."
 427     fromDouble :: Double -> a
 428     "Converts the given number to `Double`"
 429     toDouble :: a -> Double
 430
 431     a ^ b = exp (b * log a)
 432
 433     sinh x = 0.5 * (exp x - exp (neg x))
 434     cosh x = 0.5 * (exp x + exp (neg x))
 435     tanh x = (e2x - 1) / (e2x + 1)
 436       where
 437         e2x = exp (2*x)
 438
 439     asinh x = log (x + sqrt (x*x + one))
 440     acosh x = log (x + sqrt (x*x - one))
 441     atanh x = 0.5 * log ((one+x)/(one-x))
 442
 443 /// Import mathematical functions ///
 444
 445 @private
 446 importJava "java.lang.Math" where
 447     @JavaName PI
 448     piDouble :: Double
 449
 450     @JavaName sin
 451     sinDouble :: Double -> Double
 452
 453     @JavaName cos
 454     cosDouble :: Double -> Double
 455
 456     @JavaName tan
 457     tanDouble :: Double -> Double
 458
 459     @JavaName asin
 460     asinDouble :: Double -> Double
 461
 462     @JavaName acos
 463     acosDouble :: Double -> Double
 464
 465     @JavaName atan
 466     atanDouble :: Double -> Double
 467
 468     @JavaName atan2
 469     atan2Double :: Double -> Double -> Double
 470
 471     @JavaName sinh
 472     sinhDouble :: Double -> Double
 473
 474     @JavaName cosh
 475     coshDouble :: Double -> Double
 476
 477     @JavaName tanh
 478     tanhDouble :: Double -> Double
 479
 480     @JavaName exp
 481     expDouble :: Double -> Double
 482
 483     @JavaName log
 484     logDouble :: Double -> Double
 485
 486     @JavaName pow
 487     powDouble :: Double -> Double -> Double
 488
 489     @JavaName sqrt
 490     sqrtDouble :: Double -> Double
 491
 492     @JavaName ceil
 493     ceilDouble :: Double -> Double
 494
 495     @JavaName floor
 496     floorDouble :: Double -> Double
 497
 498     @JavaName round
 499     roundDouble :: Double -> Long
 500
 501     @JavaName abs
 502     absInteger :: Integer -> Integer
 503
 504     @JavaName abs
 505     absLong :: Long -> Long
 506
 507     @JavaName abs
 508     absFloat :: Float -> Float
 509
 510     @JavaName abs
 511     absDouble :: Double -> Double
 512
 513     @JavaName min
 514     minInteger :: Integer -> Integer -> Integer
 515
 516     @JavaName min
 517     minLong :: Long -> Long -> Long
 518
 519     @JavaName min
 520     minFloat :: Float -> Float -> Float
 521
 522     @JavaName min
 523     minDouble :: Double -> Double -> Double
 524
 525     @JavaName max
 526     maxInteger :: Integer -> Integer -> Integer
 527
 528     @JavaName max
 529     maxLong :: Long -> Long -> Long
 530
 531     @JavaName max
 532     maxFloat :: Float -> Float -> Float
 533
 534     @JavaName max
 535     maxDouble :: Double -> Double -> Double
 536
 537 /// Integer ///
 538
 539 @private
 540 importJava "java.lang.Byte" where
 541     @JavaName toString
 542     showByte :: Byte -> String
 543
 544     @JavaName parseByte
 545     readByte :: String -> Byte
 546
 547 instance Ord Byte where
 548     (<) = Java.bcmplt
 549     (<=) = Java.bcmple
 550     (>) = Java.bcmpgt
 551     (>=) = Java.bcmpge
 552
 553 instance Additive Byte where
 554     zero = Java.i2b Java.iconst_0
 555     (+) = Java.badd
 556
 557 instance Ring Byte where
 558     neg = Java.bneg
 559     (-) = Java.bsub
 560     one = Java.i2b Java.iconst_1
 561     (*) = Java.bmul
 562     fromInteger = Java.i2b
 563
 564 instance Show Byte where
 565     show = showByte
 566     precedence v = if v >= 0 then 0 else 100
 567
 568 instance Read Byte where
 569     read = readByte
 570
 571
 572 @private
 573 importJava "java.lang.Short" where
 574     @JavaName toString
 575     showShort :: Short -> String
 576
 577     @JavaName parseShort
 578     readShort :: String -> Short
 579
 580 instance Ord Short where
 581     (<) = Java.scmplt
 582     (<=) = Java.scmple
 583     (>) = Java.scmpgt
 584     (>=) = Java.scmpge
 585
 586 instance Additive Short where
 587     zero = Java.sconst_0
 588     (+) = Java.sadd
 589
 590 instance Ring Short where
 591     neg = Java.sneg
 592     (-) = Java.ssub
 593     one = Java.sconst_1
 594     (*) = Java.smul
 595     fromInteger = Java.i2s
 596
 597 instance Show Short where
 598     show = showShort
 599     precedence v = if v >= 0 then 0 else 100
 600
 601 instance Read Short where
 602     read = readShort
 603
 604 /// Integer ///
 605
 606 @private
 607 importJava "java.lang.Integer" where
 608     @JavaName toString
 609     showInteger :: Integer -> String
 610
 611     @JavaName parseInt
 612     readInteger :: String -> Integer
 613
 614 instance Ord Integer where
 615     (<) = Java.icmplt
 616     (<=) = Java.icmple
 617     (>) = Java.icmpgt
 618     (>=) = Java.icmpge
 619
 620 instance Additive Integer where
 621     zero = Java.iconst_0
 622     (+) = Java.iadd
 623
 624 instance Ring Integer where
 625     neg = Java.ineg
 626     (-) = Java.isub
 627     one = Java.iconst_1
 628     (*) = Java.imul
 629     fromInteger x = x
 630
 631 instance OrderedRing Integer where
 632     abs = absInteger
 633     toInteger x = x
 634
 635 instance Integral Integer where
 636     div = Java.idiv
 637     mod = Java.irem
 638
 639 instance Show Integer where
 640     show = showInteger
 641     precedence v = if v >= 0 then 0 else 100
 642
 643 instance Read Integer where
 644     read = readInteger
 645
 646 /// Long ///
 647
 648 @private
 649 importJava "java.lang.Long" where
 650     @JavaName toString
 651     showLong :: Long -> String
 652
 653     @JavaName parseLong
 654     readLong :: String -> Long
 655
 656 instance Ord Long where
 657     (<) = Java.lcmplt
 658     (<=) = Java.lcmple
 659     (>) = Java.lcmpgt
 660     (>=) = Java.lcmpge
 661
 662 instance Additive Long where
 663     zero = Java.lconst_0
 664     (+) = Java.ladd
 665
 666 instance Ring Long where
 667     neg = Java.lneg
 668     (-) = Java.lsub
 669     one = Java.lconst_1
 670     (*) = Java.lmul
 671     fromInteger = Java.i2l
 672
 673 instance OrderedRing Long where
 674     abs = absLong
 675     toInteger = Java.l2i
 676
 677 instance Integral Long where
 678     div = Java.ldiv
 679     mod = Java.lrem
 680
 681 instance Show Long where
 682     show = showLong
 683     precedence v = if v >= 0 then 0 else 100
 684
 685 instance Read Long where
 686     read = readLong
 687
 688 /// Float ///
 689
 690 importJava "java.lang.Float" where
 691     @private
 692     @JavaName compare
 693     compareFloat :: Float -> Float -> Integer
 694
 695     @private
 696     @JavaName toString
 697     showFloat :: Float -> String
 698
 699     @private
 700     @JavaName parseFloat
 701     readFloat :: String -> Float
 702
 703     "Converts 32-bit floating point number to a 32-bit integer with the same byte level representation."
 704     floatToIntBits :: Float -> Integer
 705
 706 instance Ord Float where
 707     compare = compareFloat
 708     (<) = Java.fcmplt
 709     (<=) = Java.fcmple
 710     (>) = Java.fcmpgt
 711     (>=) = Java.fcmpge
 712
 713 instance Additive Float where
 714     zero = Java.fconst_0
 715     (+) = Java.fadd
 716
 717 instance Ring Float where
 718     neg = Java.fneg
 719     (-) = Java.fsub
 720     one = Java.fconst_1
 721     (*) = Java.fmul
 722     fromInteger = Java.i2f
 723
 724 instance OrderedRing Float where
 725     abs = absFloat
 726     toInteger = Java.f2i
 727
 728 instance Real Float where
 729     (/) = Java.fdiv
 730     x ^ y = Java.d2f (powDouble (Java.f2d x) (Java.f2d y))
 731     pi = fromDouble piDouble
 732     sqrt = Java.d2f . sqrtDouble . Java.f2d
 733     exp = Java.d2f . expDouble . Java.f2d
 734     log = Java.d2f . logDouble . Java.f2d
 735     sin = Java.d2f . sinDouble . Java.f2d
 736     cos = Java.d2f . cosDouble . Java.f2d
 737     tan = Java.d2f . tanDouble . Java.f2d
 738     asin = Java.d2f . asinDouble . Java.f2d
 739     acos = Java.d2f . acosDouble . Java.f2d
 740     atan = Java.d2f . atanDouble . Java.f2d
 741     sinh = Java.d2f . sinhDouble . Java.f2d
 742     cosh = Java.d2f . coshDouble . Java.f2d
 743     tanh = Java.d2f . tanhDouble . Java.f2d
 744     floor = Java.d2f . floorDouble . Java.f2d
 745     ceil = Java.d2f . ceilDouble . Java.f2d
 746     atan2 y x = Java.d2f (atan2Double (Java.f2d y) (Java.f2d x))
 747     round = roundDouble . Java.f2d
 748     fromDouble = Java.d2f
 749     toDouble = Java.f2d
 750
 751 instance Show Float where
 752     show = showFloat
 753     precedence v = if v >= 0 then 0 else 100
 754
 755 instance Read Float where
 756     read = readFloat
 757
 758 /// Double ///
 759
 760 importJava "java.lang.Double" where
 761     @private
 762     @JavaName compare
 763     compareDouble :: Double -> Double -> Integer
 764
 765     @private
 766     @JavaName toString
 767     showDouble :: Double -> String
 768
 769     @private
 770     @JavaName parseDouble
 771     readDouble :: String -> Double
 772
 773     "Converts 64-bit floating point number to a 64-bit integer with the same byte level representation."
 774     doubleToLongBits :: Double -> Long
 775
 776     isFinite :: Double -> Boolean
 777     isNaN :: Double -> Boolean
 778     isInfinite :: Double -> Boolean
 779
 780 instance Ord Double where
 781     compare = compareDouble
 782     (<) = Java.dcmplt
 783     (<=) = Java.dcmple
 784     (>) = Java.dcmpgt
 785     (>=) = Java.dcmpge
 786
 787 instance Additive Double where
 788     zero = Java.dconst_0
 789     (+) = Java.dadd
 790
 791 instance Ring Double where
 792     neg = Java.dneg
 793     (-) = Java.dsub
 794     one = Java.dconst_1
 795     (*) = Java.dmul
 796     fromInteger = Java.i2d
 797
 798 instance OrderedRing Double where
 799     abs = absDouble
 800     toInteger = Java.d2i
 801
 802 instance Real Double where
 803     (/) = Java.ddiv
 804     (^) = powDouble
 805     pi = piDouble
 806     sqrt = sqrtDouble
 807     exp = expDouble
 808     log = logDouble
 809     sin = sinDouble
 810     cos = cosDouble
 811     tan = tanDouble
 812     asin = asinDouble
 813     acos = acosDouble
 814     atan = atanDouble
 815     sinh = sinhDouble
 816     cosh = coshDouble
 817     tanh = tanhDouble
 818     floor = floorDouble
 819     ceil = ceilDouble
 820     atan2 = atan2Double
 821     round = roundDouble
 822     fromDouble x = x
 823     toDouble x = x
 824
 825 instance Show Double where
 826     show = showDouble
 827     precedence v = if v >= 0 then 0 else 100
 828
 829 instance Read Double where
 830     read = readDouble
 831
 832 /// Character ///
 833
 834 importJava "java.lang.Character" where
 835     @JavaName toString
 836     showCharacter :: Character -> String
 837
 838     "Returns true, if the given character is a letter."
 839     isLetter :: Character -> Boolean
 840
 841     "Returns true, if the given character is a digit."
 842     isDigit :: Character -> Boolean
 843
 844 instance Ord Character where
 845     (<) = Java.ccmplt
 846     (<=) = Java.ccmple
 847     (>) = Java.ccmpgt
 848     (>=) = Java.ccmpge
 849
 850 instance Show Character where
 851     sb <+ c = sb << "'" << showCharacter c << "'"
 852
 853 "Adds a given integer to the character code."
 854 addChar :: Character -> Integer -> Character
 855 addChar = Java.cadd
 856
 857 "Subtracts a given integer from the character code."
 858 subChar :: Character -> Character -> Integer
 859 subChar = Java.csub
 860
 861 /// Functor ///
 862
 863 """
 864 The `Functor` class is used for types that can be mapped over. Instances of `Functor` should satisfy the following laws:
 865
 866     fmap id  ==  id
 867     fmap (f . g)  ==  fmap f . fmap g
 868 """
 869 class Functor f where
 870     "Lifts a pure function to the given functor."
 871     fmap :: (a -> b) -> f a -> f b
 872 /*
 873 class CoFunctor f where
 874     comap :: (a -> b) -> f b -> f a
 875 */
 876 /// Applicative ///
 877 /*
 878 class (Functor f) => Applicative f where
 879     return :: a -> f a
 880     (<*>) :: f (a -> b) -> f a -> f b
 881     (*>) :: f a -> f b -> f b
 882     (<*) :: f a -> f b -> f a
 883
 884     u *> v = pure (const id) <*> u <*> v
 885     u <* v = pure const <*> u <*> v
 886     fmap f x = pure f <*> x
 887 */
 888 /// Monad ///
 889
 890 """
 891 The `Monad` class defines the basic operations over a monad, a concept from a branch of mathematics known as category theory.
 892 From the perspective of a SCL programmer, however, it is best to think of a monad as an abstract datatype of actions.
 893 SCL's `mdo expressions provide a convenient syntax for writing monadic expressions.
 894
 895 Instances of `Monad` should satisfy the following laws:
 896
 897     return a >>= k  ==  k a
 898     m >>= return  ==  m
 899     m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 900     fmap f xs  ==  xs >>= return . f
 901 """
 902 class (Functor m) => Monad m where
 903     "Inject a value into the monadic type."
 904     return :: a -> m a
 905     "Sequentially compose two actions, passing any value produced by the first as an argument to the second."
 906     (>>=) :: m a -> (a -> m b) -> m b
 907     """
 908     The join function is the conventional monad join operator. It removes one level of monadic
 909     structure.
 910
 911     For lists, `join` concatenates a list of lists:
 912
 913         join [[1,2], [3,4]] = [1, 2, 3, 4]
 914     """
 915     join :: m (m a) -> m a
 916     join m = m >>= id
 917
 918 """
 919 Sequentially compose two actions, discarding any value produced by the first, like sequencing operators
 920 (such as the semicolon) in imperative languages."
 921 """
 922 @macro
 923 (>>) :: Monad m => m a -> m b -> m b
 924 a >> b = a >>= (\_ -> b)
 925
 926 "Left-to-right Kleisli composition of monads."
 927 (>=>) :: Monad m => (a -> m b) -> (b -> m c) -> (a -> m c)
 928 (f >=> g) x = (f x) >>= g
 929
 930 "While loop. `while cond body` executes the `body` while the `cond` is true."
 931 @inline
 932 while :: (<e> Boolean) -> (<e> a) -> <e> ()
 933 while cond body = loop ()
 934   where loop _ = if cond
 935                  then do body ; loop ()
 936                  else ()
 937
 938 """
 939 Sequences the given monadic value infinitely:
 940
 941     repeatForever m = m >> m >> m >> ...
 942 """
 943 repeatForever m = m >> repeatForever m
 944
 945 replicateM :: Monad m => Integer -> m a -> m [a]
 946 replicateM count m = loop count emptyList
 947   where
 948     loop count l | count <= 0 = return l
 949                  | otherwise  = mdo
 950                      v <- m
 951                      loop (count-1) (addList l v)
 952
 953 replicateM_ :: Monad m => Integer -> m a -> m ()
 954 replicateM_ count m | count <= 0 = return ()
 955                     | otherwise  = m >> replicateM_ (count-1) m
 956
 957 /// MonadZero ///
 958
 959 """
 960 A class of monads with zero element satisfying
 961
 962     mzero >>= f = mzero
 963 """
 964 class (Monad m) => MonadZero m where
 965     mzero :: m a
 966
 967 "Injects a boolean test to a type beloning to `MonadZero`."
 968 guard :: MonadZero m => Boolean -> m ()
 969 guard True = return ()
 970 guard False = mzero
 971
 972 /// MonadPlus ///
 973
 974 """
 975 A class of monads with associative binary operator `mplus` satisfying the following laws:
 976
 977     mplus mzero b = b
 978     mplus a mzero = a
 979     mplus (mplus a b) c = mplus a (mplus b c)
 980     mplus a b >>= k = mplus (a >>= k) (b >>= k)
 981 """
 982 class (MonadZero m) => MonadPlus m where
 983     mplus :: m a -> m a -> m a
 984
 985 /// MonadOr ///
 986
 987 """
 988 A class of monads with associative binary operator `morelse` satisfying the following laws:
 989
 990     morelse mzero b = b
 991     morelse a mzero = a
 992     morelse (morelse a b) c = morelse a (morelse b c)
 993     morelse (return a) b = return a
 994 """
 995 class (MonadZero m) => MonadOr m where
 996     morelse :: m a -> m a -> m a
 997
 998 /// FunctorE ///
 999
1000 """
1001 A class of types that can be mapped over with effectful mapping functions.
1002 """
1003 class (Functor f) => FunctorE f where
1004     """
1005     Applies the function to all elements of the container and
1006     returns the similarly shaped container with the results:
1007
1008     For lists,
1009
1010         map f [e1, e2, ..., eN] = [f e1, f e2, ..., f eN]
1011
1012     for example
1013
1014         map (*2) [1..5] = [2, 4, 6, 8, 10]
1015     """
1016     map :: (a -> <e> b) -> f a -> <e> (f b)
1017     "Calls the given function with all elements of the given container."
1018     iter :: (a -> <e> b) -> f a -> <e> ()
1019     "Calls the given function with all elements of the given container giving also the index of the element as a parameter."
1020     iterI :: (Integer -> a -> <e> b) -> f a -> <e> ()
1021
1022 "Iterates the elements of the given collection. Same as `iter` but parameters flipped."
1023 for :: FunctorE f => f a -> (a -> <e> b) -> <e> ()
1024 @macro
1025 for l f = iter f l
1026
1027 "Iterates the elements of the given collection providing also the indices of the elements. Same as `iterI` but parameters flipped."
1028 forI :: FunctorE f => f a -> (Integer -> a -> <e> b) -> <e> ()
1029 @macro
1030 forI l f = iterI f l
1031
1032 "`forN n f` calls `f` for all integers `0`, ..., `n-1`"
1033 @inline
1034 forN :: Integer -> (Integer -> <e> b) -> <e> ()
1035 forN n f = loop 0
1036   where
1037     loop i = if i < n
1038              then do f i ; loop (i+1)
1039              else ()
1040
1041 @inline
1042 mapI :: (Integer -> a -> <e> b) -> [a] -> <e> [b]
1043 mapI f l = build (\empty cons -> let
1044     len = length l
1045     loop i accum = if i < len
1046                    then loop (i+1) (cons accum (f i (l!i)))
1047                    else accum
1048   in loop 0 empty)
1049
1050 """
1051 `mapMaybe` combines `map` and `filter` functions.
1052 It applies the given function to every element of the input list. If the result
1053 is `Just x`, then `x` is added to the resulting list.
1054
1055     mapMaybe f lst = [y | x <- lst, Just y = f x]
1056 """
1057 @inline
1058 mapMaybe :: (a -> <e> Maybe b) -> [a] -> <e> [b]
1059 mapMaybe f l = build (\empty cons -> foldl (\cur x -> match f x with Just v -> cons cur v ; _ -> cur) empty l)
1060
1061 """
1062 Applies the given function to all elements of the list. Produces two lists: the first contains all elements `x`
1063 for which the function returned `Left x` and the second list contains all elements `y` for which the function
1064 returned `Right y`.
1065 """
1066 mapEither :: (a -> <e> Either b c) -> [a] -> <e> ([b], [c])
1067 mapEither f list = runProc do
1068     l = newArrayList
1069     r = newArrayList
1070     for list (\x -> match f x with
1071         Left v -> addArrayList l v
1072         Right v -> addArrayList r v)
1073     (Java.unsafeCoerce l, Java.unsafeCoerce r)
1074
1075 "`replicate n v` returns a list of length `n` such that each element is a copy of `v`."
1076 @inline
1077 replicate :: Integer -> a -> [a]
1078 replicate n v = build (\empty cons ->
1079     let aux 0 l = l
1080         aux i l = aux (i-1) (cons l v)
1081     in aux n empty
1082     )
1083
1084 /// FunctorM ///
1085
1086 class (FunctorE f) => FunctorM f where
1087     "`mapM f` is equivalent to `sequence . map f`."
1088     mapM :: Monad m => (a -> <e> m b) -> f a -> <e> m (f b)
1089     "Evaluate each action in the sequence from left to right, and collect the results."
1090     sequence :: Monad m => f (m a) -> m (f a)
1091     mapM f l = sequence (map f l)
1092
1093 /// MonadE ///
1094
1095 class (FunctorE m, Monad m) => MonadE m where
1096     bindE :: m a -> (a -> <e> m b) -> <e> m b
1097
1098 instance MonadE Maybe where
1099     bindE Nothing  _ = Nothing
1100     bindE (Just v) f = f v
1101
1102 instance MonadE (Either a) where
1103     bindE (Left v)  _ = Left v
1104     bindE (Right v) f = f v
1105
1106 instance MonadE [] where
1107     bindE l f = concatMap f l
1108
1109 /// Category ///
1110
1111 "Identity function."
1112 id :: a -> a
1113 id x = x
1114
1115 """
1116 Ignores the given value. This function is used in a situation where a function returns
1117 a value in a context where the value is not expected.
1118 """
1119 @inline
1120 ignore :: a -> ()
1121 ignore _ = ()
1122
1123 @inline
1124 ignoreM :: a -> Maybe b
1125 ignoreM _ = Nothing
1126
1127 """
1128 Composes two functions
1129     (f . g) x = f (g x)
1130 """
1131 (.) :: (b -> <e> c) -> (a -> <e> b) -> (a -> <e> c)
1132 (f . g) x = f (g x)
1133
1134 /// Sequence ///
1135
1136 "A type class for sequences. All sequences must support indexing by integers."
1137 class /*(Additive a) =>*/ Sequence a where
1138     "Length of the sequence"
1139     length :: a -> Integer
1140     "`take n s` returns the first `n` elements of the sequence `s`."
1141     take :: Integer -> a -> a
1142     "`drop n s` removes the first `n` elements of the sequence `s`."
1143     drop :: Integer -> a -> a
1144     """
1145     `sub s begin end` returns a subsequence of `s` starting from
1146     index `begin` and ending just before index `end`.
1147     """
1148     sub :: a -> Integer -> Integer -> a
1149
1150     take n v = sub v 0 (min n (length v))
1151     drop n v = sub v (min n len) len
1152       where
1153         len = length v
1154
1155 instance Sequence [a] where
1156     length = lengthList
1157     sub = subList
1158
1159 instance Sequence String where
1160     length = lengthString
1161     sub = subString
1162
1163 class IndexedSequence f where
1164     "`seq ! i` returns the `i`th element of the sequence `seq`. Indexing starts from zero."
1165     (!) :: f a -> Integer -> a
1166
1167 "Returns the first element of a sequence"
1168 @inline
1169 first :: [a] -> a
1170 first l = l!0
1171
1172 "Returns the last element of a sequence"
1173 @inline
1174 last :: [a] -> a
1175 last l = l!(length l-1)
1176
1177 instance IndexedSequence [] where
1178     (!) = getList
1179
1180 /// Boolean ///
1181
1182 """
1183 Equivalent to the boolean value `True`. The value is meant to be used in
1184 guard patterns:
1185
1186     min a b | a < b     = a
1187             | otherwise = b
1188 """
1189 @inline
1190 otherwise :: Boolean
1191 otherwise = True
1192
1193 instance Ord Boolean where
1194     compare False False = 0
1195     compare False True  = neg 1
1196     compare True  False = 1
1197     compare True  True  = 0
1198
1199 instance Show Boolean where
1200     show True = "True"
1201     show False = "False"
1202
1203 """
1204 Boolean conjunction (and). The function is a macro that evaluates the second parameter
1205 only if the first parameter is `True`.
1206
1207 <table>
1208 <tr><th>a</th><th>b</th><th>a && b</th></tr>
1209 <tr><td>True</td><td>True</td><td>True</td></tr>
1210 <tr><td>True</td><td>False</td><td>False</td></tr>
1211 <tr><td>False</td><td>not evaluated</td><td>False</td></tr>
1212 </table>
1213 """
1214 @macro
1215 (&&) :: Boolean -> Boolean ->  Boolean
1216 a && b = if a then b else False
1217
1218 """
1219 Boolean disjunction (or). The function is a macro that evaluates the second parameter
1220 only if the first parameter is `False`.
1221
1222 <table>
1223 <tr><th>a</th><th>b</th><th>a || b</th></tr>
1224 <tr><td>True</td><td>not evaluated</td><td>True</td></tr>
1225 <tr><td>False</td><td>True</td><td>True</td></tr>
1226 <tr><td>False</td><td>False</td><td>False</td></tr>
1227 </table>
1228 """
1229 @macro
1230 (||) :: Boolean -> Boolean -> Boolean
1231 a || b = if a then True else b
1232
1233 "Boolean negation"
1234 @inline
1235 not a = if a then False else True
1236
1237 /// Maybe ///
1238
1239 //data Maybe a = Nothing | Just a
1240
1241 "Given `Just x` this function returns `x`. If the parameter is `Nothing`, the function raises an exception."
1242 fromJust :: Maybe a -> a
1243 fromJust (Just a) = a
1244
1245 deriving instance (Ord a) => Ord (Maybe a)
1246 deriving instance (Show a) => Show (Maybe a)
1247
1248 instance Functor Maybe where
1249     fmap _ Nothing  = Nothing
1250     fmap f (Just x) = Just (f x)
1251
1252 instance FunctorE Maybe where
1253     map _ Nothing  = Nothing
1254     map f (Just x) = Just (f x)
1255
1256     iter _ Nothing = ()
1257     iter f (Just x) = ignore (f x)
1258
1259     iterI _ Nothing = ()
1260     iterI f (Just x) = ignore (f 0 x)
1261
1262 instance Monad Maybe where
1263     return x = Just x
1264
1265     @inline
1266     Nothing >>= _ = Nothing
1267     Just x  >>= f = f x
1268
1269     @inline
1270     join Nothing  = Nothing
1271     join (Just x) = x
1272
1273 instance MonadZero Maybe where
1274     mzero = Nothing
1275
1276 instance MonadOr Maybe where
1277     morelse a@(Just _) _ = a
1278     morelse _ b = b
1279
1280 "`execJust v f` executes the function `f` with parameter value `x`, if `v=Just x`. If `v=Nothing`, the function does nothing."
1281 @inline
1282 execJust :: Maybe a -> (a -> <e> b) -> <e> ()
1283 execJust maybeValue procedure = match maybeValue with
1284     Just v -> ignore $ procedure v
1285     _ -> ()
1286
1287 "`fromMaybe def v` returns `def` if `v=Nothing` and `x` if `v=Just x`."
1288 @inline
1289 fromMaybe :: a -> Maybe a -> a
1290 fromMaybe default maybeValue = match maybeValue with
1291     Just v -> v
1292     _ -> default
1293
1294
1295 """
1296 Provides a default value if the first parameter is Nothing.
1297 The default value is evaluated only if needed. The function
1298 can be used as an operator and is right associative so that
1299 the following is possible:
1300
1301     tryWithTheFirstMethod
1302         `orElse` tryWithTheSecondMethod
1303         `orElse` fail "Didn't succeed."
1304 """
1305 @inline
1306 orElse :: Maybe a -> (<e> a) -> <e> a
1307 orElse (Just x) _   = x
1308 orElse Nothing  def = def
1309
1310 @inline
1311 orElseM :: Maybe a -> (<e> Maybe a) -> <e> Maybe a
1312 orElseM mx@(Just x) _   = mx
1313 orElseM Nothing     def = def
1314
1315 /// Either ///
1316
1317 """
1318 The Either type represents values with two possibilities: a value of type `Either a b` is either `Left a` or `Right b`.
1319
1320 The `Either` type is sometimes used to represent a value which is either correct or an error; by convention, the `Left` constructor
1321 is used to hold an error value and the `Right` constructor is used to hold a correct value (mnemonic: "right" also means "correct").
1322 """
1323 @JavaType "org.simantics.scl.runtime.either.Either"
1324 data Either a b =
1325     @JavaType "org.simantics.scl.runtime.either.Left"
1326     @FieldNames [value]
1327     Left a
1328   | @JavaType "org.simantics.scl.runtime.either.Right"
1329     @FieldNames [value]
1330     Right b
1331
1332 deriving instance (Ord a, Ord b) => Ord (Either a b)
1333 deriving instance (Show a, Show b) => Show (Either a b)
1334
1335 instance Functor (Either a) where
1336     fmap _ (Left x)  = Left x
1337     fmap f (Right y) = Right (f y)
1338
1339 instance FunctorE (Either a) where
1340     map _ (Left x)  = Left x
1341     map f (Right y) = Right (f y)
1342
1343     iter _ (Left x) = ()
1344     iter f (Right y) = ignore (f y)
1345
1346     iterI _ (Left x) = ()
1347     iterI f (Right y) = ignore (f 0 y)
1348
1349 instance Monad (Either b) where
1350     return y = Right y
1351
1352     Left x  >>= _ = Left x
1353     Right y >>= f = f y
1354
1355     join (Left x)  = Left x
1356     join (Right y) = y
1357
1358 /// String ///
1359
1360 importJava "java.lang.String" where
1361     @private
1362     @JavaName "concat"
1363     concatString :: String -> String -> String
1364     @private
1365     @JavaName "compareTo"
1366     compareString :: String -> String -> Integer
1367     @private
1368     @JavaName "length"
1369     lengthString :: String -> Integer
1370
1371     """
1372     `replaceString original pattern replacement` replaces all occurrences of `pattern` in the string by `replacement`.
1373     """
1374     @JavaName replace
1375     replaceString :: String -> String -> String -> String
1376
1377     @private
1378     @JavaName split
1379     splitString_ :: String -> String -> Array String
1380
1381     """
1382     `indexOf string s` finds the first occurrence of `s` from `string` and returns its index.
1383     If the `s` does not occur in the string, return `-1`."
1384     """
1385     @JavaName indexOf
1386     indexOf :: String -> String -> Integer
1387
1388     "Works like `indexOf` but starts searching from the given index instead of the beginning of the string."
1389     @JavaName indexOf
1390     indexOfStartingFrom :: String -> String -> Integer -> Integer
1391
1392     "Works like `indexOf` but returns the index of the last occurrence."
1393     @JavaName lastIndexOf
1394     lastIndexOf :: String -> String -> Integer
1395
1396     "Works like `lastIndexOf` but starts searching from the given index instead of the end of the string."
1397     @JavaName lastIndexOf
1398     lastIndexOfStartingFrom :: String -> String -> Integer -> Integer
1399
1400     @private
1401     @JavaName substring
1402     subString :: String -> Integer -> Integer -> String
1403
1404     """
1405     `regionMatches str1 offset1 str2 offset2 len` tests whether
1406     `sub str1 offset1 (offset1+len) == sub str2 offset2 (offset2+len)`.
1407     """
1408     regionMatches :: String -> Integer -> String -> Integer -> Integer -> Boolean
1409
1410     "`startsWith string prefix` returns true if the string begins with the given prefix."
1411     startsWith :: String -> String -> Boolean
1412
1413     "`endsWith string suffix` returns true if the string ends with the given prefix."
1414     endsWith :: String -> String -> Boolean
1415
1416     "Removes leading and trailing whitespace from the string."
1417     trim :: String -> String
1418
1419     "`contains string s` returns true if `string` contains `s` as a substring."
1420     contains :: String -> String -> Boolean
1421
1422     "`charAt string i` returns the `i`th character of the string."
1423     charAt :: String -> Integer -> Character
1424
1425     "Converts all letters of the string to lower case."
1426     toLowerCase :: String -> String
1427     "Converts all letters of the string to upper case."
1428     toUpperCase :: String -> String
1429
1430     "Creates a string from a vector of characters."
1431     @JavaName "<init>"
1432     string :: Vector Character -> String
1433
1434     getBytes :: String -> String -> ByteArray
1435
1436 getBytesUTF8 :: String -> ByteArray
1437 getBytesUTF8 str = getBytes str "UTF-8"
1438
1439 instance Ord String where
1440     compare = compareString
1441
1442 instance Additive String where
1443     zero = ""
1444     (+) = concatString
1445     sum ss = runProc (StringBuilder.toString $ foldl StringBuilder.appendString StringBuilder.new ss)
1446
1447 @private
1448 importJava "org.simantics.scl.runtime.string.StringEscape" where
1449     appendEscapedString :: StringBuilder.T -> String -> <Proc> StringBuilder.T
1450
1451 instance Show String where
1452     showForPrinting = id
1453     sb <+ v = (appendEscapedString (sb << "\"") v) << "\""
1454
1455 instance Read String where
1456     read str = str
1457
1458 @deprecated "Instead of 'splitString text pattern', write 'split pattern text' (note change in the parameter order)."
1459 "`splitString text pattern` splits the string into a list of string where the parts are sepratated in the original list by the given pattern."
1460 splitString :: String -> String -> [String]
1461 splitString source pattern = arrayToList $ splitString_ source pattern
1462
1463 """
1464 `split pattern text` splits `text` around matches of the given regular expression `pattern`.
1465
1466 This function works as if by invoking the two-argument split method with the given expression and a limit argument of zero. Trailing empty strings are therefore not included in the resulting array.
1467
1468 The string "boo:and:foo", for example, yields the following results with these expressions:
1469
1470     Regex   Result
1471     :       { "boo", "and", "foo" }
1472     o       { "b", "", ":and:f" }
1473 """
1474 split :: String -> String -> [String]
1475 split pattern text = arrayToList $ splitString_ text pattern
1476
1477 /// Tuple0 ///
1478
1479 instance Ord () where
1480     compare () () = 0
1481
1482 instance Additive () where
1483     zero = ()
1484     () + () = ()
1485
1486 instance Show () where
1487     show () = "()"
1488
1489 /// Tuple2 ///
1490
1491 "Gives the first element of a pair."
1492 @inline
1493 fst :: (a,b) -> a
1494 fst (x,y) = x
1495
1496 "Gives the second element of a pair."
1497 @inline
1498 snd :: (a,b) -> b
1499 snd (x,y) = y
1500
1501 @inline
1502 mapFst :: (a -> b) -> (a,c) -> (b,c)
1503 mapFst f (x,y) = (f x, y)
1504
1505 @inline
1506 mapSnd :: (a -> b) -> (c,a) -> (c,b)
1507 mapSnd f (x,y) = (x, f y)
1508
1509 instance (Ord a, Ord b) => Ord (a, b) where
1510     compare (a0, b0) (a1, b1) = compare a0 a1 &<& compare b0 b1
1511
1512 instance (Additive a, Additive b) => Additive (a, b) where
1513     zero = (zero, zero)
1514     (a0, b0) + (a1, b1) = (a0+a1, b0+b1)
1515
1516 instance Functor ((,) a) where
1517     fmap f (a,b) = (a, f b)
1518
1519 instance (Show a, Show b) => Show (a, b) where
1520     sb <+ (x, y) = sb << "(" <+ x << ", " <+ y << ")"
1521
1522 /// Tuple3 ///
1523
1524 instance (Ord a, Ord b, Ord c) => Ord (a, b, c) where
1525     compare (a0, b0, c0) (a1, b1, c1) = compare a0 a1 &<& compare b0 b1 &<& compare c0 c1
1526
1527 instance (Additive a, Additive b, Additive c) => Additive (a, b, c) where
1528     zero = (zero, zero, zero)
1529     (a0, b0, c0) + (a1, b1, c1) = (a0+a1, b0+b1, c0+c1)
1530
1531 instance Functor ((,,) a b) where
1532     fmap f (a,b,c) = (a, b, f c)
1533
1534 instance (Show a, Show b, Show c) => Show (a, b, c) where
1535     sb <+ (x, y, z) = sb << "(" <+ x << ", " <+ y << ", " <+ z << ")"
1536
1537 /// Tuple4 ///
1538
1539 instance (Ord a, Ord b, Ord c, Ord d) => Ord (a, b, c, d) where
1540     compare (a0, b0, c0, d0) (a1, b1, c1, d1) =
1541         compare a0 a1 &<& compare b0 b1 &<& compare c0 c1 &<& compare d0 d1
1542
1543 instance (Additive a, Additive b, Additive c, Additive d) => Additive (a, b, c, d) where
1544     zero = (zero, zero, zero, zero)
1545     (a0, b0, c0, d0) + (a1, b1, c1, d1) = (a0+a1, b0+b1, c0+c1, d0+d1)
1546
1547 instance Functor ((,,,) a b c) where
1548     fmap f (a,b,c,d) = (a, b, c, f d)
1549
1550 instance (Show a, Show b, Show c, Show d) => Show (a, b, c, d) where
1551     sb <+ (x, y, z, w) = sb << "(" <+ x << ", " <+ y << ", " <+ z << ", " <+ w << ")"
1552
1553 /// Tuple5 ///
1554
1555 instance (Ord a, Ord b, Ord c, Ord d, Ord e) => Ord (a, b, c, d, e) where
1556     compare (a0, b0, c0, d0, e0) (a1, b1, c1, d1, e1) =
1557         compare a0 a1 &<& compare b0 b1 &<& compare c0 c1 &<& compare d0 d1 &<& compare e0 e1
1558
1559 instance (Additive a, Additive b, Additive c, Additive d, Additive e) => Additive (a, b, c, d, e) where
1560     zero = (zero, zero, zero, zero, zero)
1561     (a0, b0, c0, d0, e0) + (a1, b1, c1, d1, e1) = (a0+a1, b0+b1, c0+c1, d0+d1, e0+e1)
1562
1563 instance Functor ((,,,,) a b c d) where
1564     fmap f (a,b,c,d,e) = (a, b, c, d, f e)
1565
1566 /// Lists ///
1567
1568 instance (Ord a) => Ord [a] where
1569     compare a b = loop 0
1570       where
1571         lA = length a
1572         lB = length b
1573         loop i = if i >= lA
1574                  then (if i >= lB then 0 else -1)
1575                  else if i >= lB
1576                  then 1
1577                  else compare (a!i) (b!i) &<& loop (i+1)
1578
1579 instance Functor [] where
1580     fmap = mapList
1581
1582 instance FunctorE [] where
1583     map = mapEList
1584     iter = iterList
1585     iterI = iterIList
1586
1587 instance Monad [] where
1588     return x = singletonList x
1589     l >>= f  = concatMap f l
1590     join l   = l >>= id
1591
1592 instance MonadZero [] where
1593     mzero = emptyList
1594
1595 instance MonadPlus [] where
1596     mplus = appendList
1597
1598 instance Additive [a] where
1599     zero = emptyList
1600     (+) = appendList
1601
1602 instance FunctorM [] where
1603     sequence = foldl (\m mel -> m >>= \l -> mel >>= \el -> return (addList l el)) (return emptyList)
1604     mapM f l = sequence (map f l)
1605
1606 "Appends the string representations of all elements of the list to the string builder and separates the values with the given separator."
1607 printWithSeparator :: Show a => StringBuilder.T -> String -> [a] -> <Proc> StringBuilder.T
1608 printWithSeparator sb sep l = loop 0
1609   where
1610     len = length l
1611     loop i = if i >= len then sb
1612              else do
1613                  (if i==0 then sb else sb << sep) <+ l!i
1614                  loop (i+1)
1615
1616 """
1617 Joins the string representations of the list of values with the given separator.
1618
1619 See [intercalate](#intercalate) for an alternative that works with Strings
1620 and doesn't escape its arguments.
1621 """
1622 joinWithSeparator :: Show a => String -> [a] -> String
1623 joinWithSeparator separator values = runProc (
1624     StringBuilder.toString $ printWithSeparator StringBuilder.new separator values)
1625
1626
1627 """
1628 The intercalate function takes a String and a list of Strings
1629 and concatenates the list after interspersing the first argument
1630 between each element of the list.
1631
1632 See also more generic [joinWithSeparator](#joinWithSeparator)
1633 which escapes its arguments using `show`.
1634 """
1635 intercalate :: String -> [String] -> String
1636 intercalate separator strings = do
1637     l = length strings
1638     if l == 0
1639     then ""
1640     else if l == 1
1641     then strings!0
1642     else runProc do
1643         sb = StringBuilder.new
1644         sb << strings!0
1645         loop i | i == l = ()
1646                | otherwise = do
1647             sb << separator << strings!i
1648             loop (i+1)
1649         loop 1
1650         StringBuilder.toString sb
1651
1652 instance (Show a) => Show [a] where
1653     sb <+ l = do
1654         len = length l
1655         loop i = if i < len
1656                  then do
1657                      if (i>0) then sb << ", " else sb
1658                      sb <+ l!i
1659                      loop (i+1)
1660                  else sb << "]"
1661         sb << "["
1662         loop 0
1663
1664 importJava "java.util.List" where
1665     "`getList l i` returns the `i`th element of the list `l`. Indexing starts from zero. You can also use the `!` infix function for this purpose."
1666     @JavaName get
1667     getList :: [a] -> Integer -> a
1668
1669     @private
1670     @JavaName size
1671     lengthList :: [a] -> Integer
1672
1673     @private
1674     subList :: [a] -> Integer -> Integer -> [a]
1675
1676     @private
1677     isEmpty :: [a] -> Boolean
1678
1679 @private
1680 importJava "java.util.Collections" where
1681     emptyList :: [a]
1682     //singletonList :: a -> [a]
1683
1684 /*
1685 @inline
1686 emptyList :: [a]
1687 emptyList = build (\empty cons -> empty)
1688 */
1689
1690 "Creates a list with exectly one element."
1691 @inline
1692 singletonList :: a -> [a]
1693 singletonList v = build (\empty cons -> cons empty v)
1694
1695 /*
1696 // foldl f i (a + b) = foldl f (foldl f i a) b
1697
1698 appendList :: [a] -> [a] -> [a]
1699 appendList a b = build (\empty cons -> foldl cons (foldl cons empty a) b)
1700 */
1701
1702 importJava "org.simantics.scl.runtime.list.ShareableList" where
1703     "Concatenates two lists."
1704     @private
1705     @JavaName "concat"
1706     appendList :: [a] -> [a] -> [a]
1707
1708     "Adds the given value to the end of the list."
1709     @JavaName "add"
1710     addList :: [a] -> a -> [a]
1711
1712 @private
1713 importJava "java.util.ArrayList" where
1714     data ArrayList a
1715
1716     @JavaName "<init>"
1717     newArrayList :: <Proc> ArrayList a
1718
1719     @JavaName add
1720     addArrayList :: ArrayList a -> a -> <Proc> ()
1721
1722 """
1723 A primitive for constructing a list by `empty` and `cons` operations given to the function given as a parameter to this function.
1724 For example:
1725
1726     build (\empty cons -> cons (cons (cons empty 1) 2) 3)
1727
1728 produces
1729
1730     [1, 2, 3]
1731
1732 The SCL compiler makes the following optimization when encountering `build` and `foldl` functions after inlining:
1733
1734     foldl f i (build g) = g i f
1735 """
1736 @inline 2
1737 build :: forall b e2. (forall a e1. a -> (a -> b -> <e1> a) -> <e1,e2> a) -> <e2> [b]
1738 build f = runProc do
1739     l = newArrayList
1740     f () (\_ v -> addArrayList l v)
1741     Java.unsafeCoerce l
1742
1743 "A specific implementation of `map` for lists."
1744 @private
1745 @inline
1746 mapEList :: (a -> <e> b) -> [a] -> <e> [b]
1747 mapEList f l = build (\empty cons -> foldl (\cur x -> cons cur (f x)) empty l)
1748
1749 "A specific implementation of `fmap` for lists."
1750 @inline
1751 mapList :: (a -> b) -> [a] -> [b]
1752 mapList f l = build (\empty cons -> foldl (\cur x -> cons cur (f x)) empty l)
1753
1754 "`guardList v` returns a singleton `[()]` if `v=True` and the empty list if `v=False`."
1755 @inline
1756 guardList :: Boolean -> [()]
1757 guardList cond = build (\empty cons -> if cond then cons empty () else empty)
1758
1759 """
1760 `concatMap` combines `map` and `join` functions.
1761 It maps the elements of a given list to lists with the given function and concatenates the results.
1762
1763     concatMap f lst = join (map f lst) = [y | x <- lst, y <- f x]
1764 """
1765 @inline
1766 concatMap :: (a -> <e> [b]) -> [a] -> <e> [b]
1767 concatMap f l = build (\empty cons -> foldl (\cur le -> foldl cons cur (f le)) empty l)
1768
1769 """
1770 Applies the given function to the elements of the lists until the function returns something
1771 else than `Nothing`. This return value is also returned as a result of this function.
1772 """
1773 @inline
1774 mapFirst :: (a -> <e> Maybe b) -> [a] -> <e> Maybe b
1775 mapFirst f l = loop 0
1776   where
1777     len = length l
1778     loop i = if i == len
1779              then Nothing
1780              else match f (l!i) with
1781                  r @ (Just _) -> r
1782                  Nothing -> loop (i+1)
1783
1784 """
1785     foldl op initialValue list
1786
1787 applies a binary operator `op` to all elements of `list` from left to right
1788 starting with `initialValue`. For example,
1789
1790     foldl op init [x1, x2, x3, x4] = (((init `op` x1) `op` x2) `op` x3) `op` x4
1791 """
1792 @inline 2
1793 foldl :: forall a b e. (a -> b -> <e> a) -> a -> [b] -> <e> a
1794 foldl f initial l = loop initial 0
1795   where
1796     len = length l
1797     loop cur i = if i==len
1798                  then cur
1799                  else loop (f cur (l!i)) (i+1)
1800
1801 foldlI :: forall a b e. (Integer -> a -> b -> <e> a) -> a -> [b] -> <e> a
1802 foldlI f initial l = loop initial 0
1803   where
1804     len = length l
1805     loop cur i = if i==len
1806                  then cur
1807                  else loop (f i cur (l!i)) (i+1)
1808
1809 scanl :: (b -> a -> <e> b) -> b -> [a] -> <e> [b]
1810 scanl f initial l = build (\empty cons -> let
1811     len = length l
1812     loop cur i accum = let nl = cons accum cur
1813                            in if i==len
1814                            then nl
1815                             else loop (f cur (l!i)) (i+1) nl
1816   in loop initial 0 empty)
1817
1818 "`foldr` is defined like `foldl` but it process the list from right to left."
1819 @inline
1820 foldr :: (b -> a -> <e> a) -> a -> [b] -> <e> a
1821 foldr f initial l = loop initial (length l - 1)
1822   where
1823     loop cur i = if i < 0
1824                  then cur
1825                  else loop (f (l!i) cur) (i-1)
1826
1827 foldr1 :: (a -> a -> <e> a) -> [a] -> <e> a
1828 foldr1 f l = loop (l!(len-1)) (len-2)
1829   where
1830     len = length l
1831     loop cur i = if i < 0
1832                  then cur
1833                  else loop (f (l!i) cur) (i-1)
1834
1835 """
1836 `filter pred lst` returns those elements of `lst` that the predicate `pred` accepts. For example
1837
1838     filter (> 3) [1, 2, 3, 4, 5, 6] = [4, 5, 6]
1839 """
1840 @inline
1841 filter :: (a -> <e> Boolean) -> [a] -> <e> [a]
1842 filter p l = build (\empty cons -> foldl (\cur x -> if p x then cons cur x else cur) empty l)
1843
1844 """
1845 Takes those elements of the input list that match `(Just x)` and adds the contents to the resulting list. For example,
1846
1847     filterJust [Just 1, Nothing, Just 5] = [1, 5]
1848 """
1849 @inline
1850 filterJust :: [Maybe a] -> [a]
1851 filterJust l = build (\empty cons -> foldl (\cur x -> match x with Just v -> cons cur v ; _ -> cur) empty l)
1852
1853 listToMaybe :: [a] -> Maybe a
1854 listToMaybe l = if isEmpty l then Nothing else Just (l!0)
1855
1856 maybeToList :: Maybe a -> [a]
1857 maybeToList (Just a) = [a]
1858 maybeToList _ = []
1859
1860 """
1861 `takeWhile p l`, returns the longest prefix (possibly empty) of list `l` of elements that satisfy `p`
1862 """
1863 takeWhile :: (a -> <e> Boolean) -> [a] -> <e> [a]
1864 takeWhile f l = loop 0
1865   where
1866     len = length l
1867     loop i | i == len  = l
1868            | f (l!i)   = loop (i+1)
1869            | otherwise = take i l
1870
1871 partition :: (a -> <e> Boolean) -> [a] -> <e> ([a], [a])
1872 partition p l = runProc do
1873     res1 = newArrayList
1874     res2 = newArrayList
1875     for l (\el ->
1876         if p el
1877         then addArrayList res1 el
1878         else addArrayList res2 el
1879     )
1880     (Java.unsafeCoerce res1, Java.unsafeCoerce res2)
1881
1882 """
1883 `range begin end` produces a list of consecutive integers starting from `begin` and ending to `end` (including `end`).
1884 The compiler supports syntactic sugar `[begin..end]` for this function.
1885 """
1886 @inline
1887 range :: Integer -> Integer -> [Integer]
1888 range first last = build (\empty cons -> do
1889     loop i cur = if i > last then cur else loop (i+1) (cons cur i)
1890     loop first empty)
1891
1892 "A specific implementation of `iter` for lists."
1893 @inline
1894 iterList :: (a -> <e> b) -> [a] -> <e> ()
1895 iterList f l = foldl (\_ x -> ignore (f x)) () l
1896
1897 "A specific implementation of `iterI` for lists."
1898 @inline
1899 iterIList :: (Integer -> a -> <e> b) -> [a] -> <e> ()
1900 iterIList f l = do foldl (\i x -> do f i x ; i+1) 0 l ; ()
1901
1902 """
1903 Generates a list from a given starting state and iteration function.
1904 For example
1905
1906     let nextState 0 = Nothing
1907         nextState i = Just (i, i `div` 2)
1908     in  unfoldr nextState 30
1909
1910 produces
1911
1912     [30, 15, 7, 3, 1]
1913 """
1914 @inline
1915 unfoldr :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
1916 unfoldr f s = build (\empty cons -> do
1917     loop s cur =
1918         match f s with
1919             Just (el,newS) -> loop newS (cons cur el)
1920             _ -> cur
1921     loop s empty)
1922
1923 importJava "org.simantics.scl.runtime.Lists" where
1924     /*
1925     @private
1926     @JavaName map
1927     mapList :: (a -> b) -> [a] -> [b]
1928     @private
1929     @JavaName map
1930     mapEList :: (a -> <e> b) -> [a] -> <e> [b]
1931     @private
1932     @JavaName iter
1933     iterList :: (a -> <e> ()) -> [a] -> <e> ()
1934     concatMap :: (a -> <e> [b]) -> [a] -> <e> [b]
1935     */
1936     """
1937     Combines two lists into one list of pairs. The length of the resulting list is the length of the smallest input list.
1938
1939         zip [1, 2, 3, 4, 5] ['a', 'b', 'c'] = [(1, 'a'), (2, 'b'), (3, 'c')]
1940     """
1941     zip :: [a] -> [b] -> [(a,b)]
1942     "Combines two lists by using the given function for combining the elements. The length of the resulting list is the length of the smallest input list."
1943     zipWith :: (a -> b -> <e> c) -> [a] -> [b] -> <e> [c]
1944     """
1945     Produces two lists from one list of pairs.
1946
1947         unzip [(1, 'a'), (2, 'b'), (3, 'c')] = ([1, 2, 3], ['a', 'b', 'c'])
1948     """
1949     unzip :: [(a,b)] -> ([a],[b])
1950
1951     //"@filter p l@ returns those elements of @l@ that the predicate @p@ accepts."
1952     //filter :: (a -> <e> Boolean) -> [a] -> <e> [a]
1953     //filterJust :: [Maybe a] -> [a]
1954     /*
1955     foldl :: (a -> b -> <e> a) -> a -> [b] -> <e> a
1956     */
1957     "Like `foldl` but assumes that the list is non-empty so the initial is not needed."
1958     foldl1 :: (a -> a -> <e> a) -> [a] -> <e> a
1959     //unfoldr :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
1960
1961     "Sorts the list using the given comparator."
1962     sortWith :: (a -> a -> <e> Integer) -> [a] -> <e> [a]
1963
1964     """
1965     Given a list of key-value pairs, the function produces a function that finds a value
1966     efficiently for the given key.
1967     """
1968     index :: [(a,b)] -> a -> Maybe b
1969
1970     """
1971     Given a list of elements, the function produces its characteristic function.
1972     """
1973     indexSet :: [a] -> a -> Boolean
1974
1975     """
1976     Given a list of values and a function computing a key for each value, the function produces a function that finds a value
1977     effeciently for the given key.
1978     """
1979     indexBy ::  (a -> <e> b) -> [a] -> <e> (b -> Maybe a)
1980
1981     "Works like `index` but uses the given functions as hash codes and equality."
1982     indexWith :: (a -> Integer) -> (a -> a -> Boolean) -> [(a,b)] -> a -> Maybe b
1983
1984     "Groups a list values by a key computed by the given function."
1985     groupBy :: (a -> <e> b) -> [a] -> <e> [(b, [a])]
1986
1987     "Groups a list of key-value pairs by the keys."
1988     group :: [(a,b)] -> [(a, [b])]
1989
1990     "Composition of index and groupBy."
1991     indexGroupBy :: (a -> <e> b) -> [a] -> <e> (b -> [a])
1992
1993     "Composition of index and group."
1994     indexGroup :: [(a,b)] -> a -> [b]
1995
1996     groupWith :: (b -> Integer) -> (b -> b -> Boolean) -> (a -> <e> b) -> (a -> <e> c) -> [a] -> <e> [(b, [c])]
1997
1998     "Removes duplicates (all but the first occurrence) from the list but otherwise preserves the order of the elements."
1999     unique :: [a] -> [a]
2000
2001     "Like `unique`, but uses the given function for finding the key values used for uniqueness testing."
2002     uniqueBy :: (a -> b) -> [a] -> [a]
2003
2004     "Works like `unique` but uses the given function for equality tests."
2005     uniqueWith :: (a -> a -> Boolean) -> [a] -> [a]
2006
2007     "Works like `\\\\` but uses the given function for equality tests."
2008     deleteAllBy :: (a -> a -> Boolean) -> [a] -> [a] -> [a]
2009
2010     @private
2011     listDifference :: [a] -> [a] -> [a]
2012
2013     //range :: Integer -> Integer -> [Integer]
2014
2015     //build :: (forall a. a -> (a -> b -> <e> a) -> <e> a) -> <e> [b]
2016
2017 "`elem el lst` return true, if `el` occurs in the list `lst`."
2018 elem :: a -> [a] -> Boolean
2019 elem el l = loop 0
2020   where
2021     len = length l
2022     loop i | i < len = if el == l!i
2023                        then True
2024                        else loop (i+1)
2025            | otherwise = False
2026
2027 "`elemMaybe v1 (Just v2)` returns true if `v1 == v2`. `elemMaybe v1 Nothing` is always false."
2028 elemMaybe :: a -> Maybe a -> Boolean
2029 elemMaybe el m = match m with
2030     Just el2 -> el == el2
2031     Nothing -> False
2032
2033 "`elemIndex el lst` returns the index of the first element in the given list `lst` which is equal (by ==) to the query element, or Nothing if there is no such element."
2034 elemIndex :: a -> [a] -> Maybe Integer
2035 elemIndex el l = loop 0
2036   where
2037     len = length l
2038     loop i | i < len = if el == l!i
2039                        then Just i
2040                        else loop (i+1)
2041            | otherwise = Nothing
2042
2043 """
2044 Computes a list that contains only elements that belongs to both input lists.
2045 """
2046 intersect :: [a] -> [a] -> [a]
2047 intersect a b = filter f a
2048   where
2049     f e = elem e b
2050
2051 "Reverses a given list. For example, `reverse [1,2,3] = [3,2,1]`"
2052 reverse :: [a] -> [a]
2053 reverse l = [l!(len-i) | i <- [1..len]]
2054   where
2055     len = length l
2056
2057 """
2058 Transposes the rows and columns of its argument. For example,
2059
2060     transpose [[1,2,3],[4,5,6]] == [[1,4],[2,5],[3,6]]
2061     transpose [[1,2],[3,4,5]] == [[1,3],[2,4],[5]]
2062 """
2063 transpose :: [[a]] -> [[a]]
2064 transpose xss = [[xs!i | xs <- xss, i < length xs]
2065                 | i <- [0..maximum [length xs | xs <- xss]-1]]
2066
2067 "Works like `unfoldr` but generates the list from right to left."
2068 unfoldl :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
2069 unfoldl f seed = reverse $ unfoldr f seed
2070
2071 "Removes the first element of the list, if the list is non-empty."
2072 tail :: [a] -> [a]
2073 tail l = if len < 2 then emptyList else subList l 1 len
2074   where
2075     len = length l
2076
2077 "Tries to find the given key from the list of key-value pairs and returns the corresponding value."
2078 lookup ::  a -> [(a, b)] -> Maybe b
2079 lookup el l = do
2080     len = length l
2081     loop i = if i < len
2082              then match l!i with
2083                (a,b) | a == el   -> Just b
2084                      | otherwise -> loop (i+1)
2085              else Nothing
2086     loop 0
2087
2088 "Conjunction over a list."
2089 @inline
2090 and :: [Boolean] -> Boolean
2091 and = foldl (&&) True
2092
2093 "Disjunction over a list."
2094 @inline
2095 or :: [Boolean] -> Boolean
2096 or  = foldl (||) False
2097
2098 """
2099 `any pred lst` tests whether the predicate `pred` holds some element of `lst`.
2100 It returns immediately when it encounters the first value satisfying the predicate.
2101 """
2102 any :: (a -> <e> Boolean) -> [a] -> <e> Boolean
2103 any p =  or . map p
2104
2105 """
2106 `all pred lst` tests whether the predicate `pred` holds for all elements of `lst`.
2107 It returns immediately when it encounters the first value not satisfying the predicate.
2108 """
2109 all :: (a -> <e> Boolean) -> [a] -> <e> Boolean
2110 all p =  and . map p
2111
2112 """
2113 Returns the first element of the list satisfying the given condition,
2114 or `Nothing` if there is no such element.
2115 """
2116 findFirst :: (a -> <e> Boolean) -> [a] -> <e> Maybe a
2117 findFirst p l = loop 0
2118   where
2119     len = length l
2120     loop i = if i < len
2121              then let el = l!i in
2122                   if p el
2123                   then Just el
2124                   else loop (i+1)
2125              else Nothing
2126     loop 0
2127
2128
2129 """
2130 Sorts the given list using its default order.
2131 """
2132 @inline
2133 sort :: Ord a => [a] -> [a]
2134 sort = sortWith compare
2135
2136 """
2137 Sorts the lists by the values computed by the first function.
2138 For example
2139
2140     sortBy snd [(1,5), (2,3), (3,4)] = [(2,3), (3,4), (1,5)]
2141 """
2142 @inline
2143 sortBy :: Ord b => (a -> <e> b) -> [a] -> <e> [a]
2144 sortBy f l = sortWith (\x y -> compare (f x) (f y)) l
2145 // This is faster if f is slow, but will generate more auxiliary structures
2146 //sortBy f l = map snd (sortWith (\(x,_) (y,_) -> compare x y) [(f x, x) | x <- l])
2147
2148 "`a \\\\ b` removes all elements of `b` from the list `a`."
2149 (\\) :: [a] -> [a] -> [a]
2150 (\\) = listDifference
2151
2152 /// Dynamic ///
2153
2154 importJava "java.lang.Object" where
2155     "A data type that can represent any value."
2156     data Dynamic
2157
2158     @private
2159     @JavaName toString
2160     showDynamic :: Dynamic -> String
2161
2162 instance Show Dynamic where
2163     show = showDynamic
2164
2165 "Converts a value to `Dynamic` type."
2166 toDynamic :: a -> Dynamic
2167 toDynamic = Java.unsafeCoerce
2168
2169 "Converts a `Dynamic` value to a required value, or fails if the conversion is not possible."
2170 importJava "org.simantics.scl.compiler.runtime.ValueConversion" where
2171     fromDynamic :: Typeable a => Dynamic -> a
2172
2173 /// Procedures ///
2174
2175 importJava "org.simantics.scl.runtime.procedure.Ref" where
2176     "A mutable reference to a value of type `a`."
2177     data Ref a
2178
2179     "Creates a new reference with the given initial value."
2180     @JavaName "<init>"
2181     ref :: a -> <Proc> (Ref a)
2182
2183     "Returns the current value of the reference."
2184     @JavaName "value"
2185     getRef :: Ref a -> <Proc> a
2186
2187     "Sets a new value for the reference."
2188     @JavaName "<set>value"
2189     (:=) :: Ref a -> a -> <Proc> ()
2190
2191 instance Show (Ref a) where
2192     show _ = "<reference>"
2193
2194 importJava "org.simantics.scl.runtime.reporting.SCLReporting" where
2195     "Prints the given string to the console."
2196     @JavaName "print"
2197     printString :: String -> <Proc> ()
2198     "Prints an error message to the console."
2199     printError :: String -> <Proc> ()
2200     "Reports that certain amount of work has been done for the current task."
2201     didWork :: Double -> <Proc> ()
2202     """
2203     `printingToFile "fileName" expression` executes the `expression` so that all its console prints
2204     are written to the file given as a first parameter.
2205     """
2206     printingToFile :: String -> (<e> a) -> <e> a
2207     """
2208     `printErrorsAsNormalPrints expression` executes the `expression` so that all its error prints
2209     are printed as normal prints. This is useful mainly in testing scripts for checking that the implementations
2210     give proper error messages with invalid inputs.
2211     """
2212     printErrorsAsNormalPrints :: (<e> a) -> <e> a
2213     """
2214     `disablePrintingForCommand expression` executes the `expression` so that it does not print return values.
2215     Errors are printed normally.
2216     """
2217     disablePrintingForCommand :: (<e> a) -> <e> a
2218
2219
2220 importJava "org.simantics.scl.runtime.procedure.Procedures" where
2221     "Returns `True` if the current thread has been interrupted."
2222     isInterrupted :: <Proc> Boolean
2223     "Checks whether the current thread has been interrupted and throws an exception if it is."
2224     checkInterrupted :: <Proc> ()
2225     "Generates a random identifier."
2226     generateUID :: <Proc> String
2227
2228     "Executes the given expression and catches certain class of exceptions (specified by the catch handler that is given as a second parameter.)"
2229     @JavaName catch_
2230     catch :: VecComp ex => (<e,Exception> a) -> (ex -> <e> a) -> <e> a
2231
2232 importJava "java.lang.Throwable" where
2233     data Throwable
2234     @private
2235     @JavaName toString
2236     showThrowable :: Throwable -> String
2237     @private
2238     @JavaName getMessage
2239     getMessageThrowable :: Throwable -> String
2240     @private
2241     @JavaName getCause
2242     getCauseThrowable :: Throwable -> Maybe Throwable
2243 importJava "java.lang.Exception" where
2244     data Exception
2245     @private
2246     @JavaName toString
2247     showException :: Exception -> String
2248
2249 instance Show Throwable where
2250     show = showThrowable
2251 instance Show Exception where
2252     show = showException
2253
2254 class Throwable e where
2255     toThrowable :: e -> Throwable
2256
2257 messageOfException :: Throwable e => e -> String
2258 messageOfException = getMessageThrowable . toThrowable
2259
2260 causeOfException :: Throwable e => e -> Maybe Throwable
2261 causeOfException = getCauseThrowable . toThrowable
2262
2263 instance Throwable Throwable where
2264     toThrowable = id
2265 instance Throwable Exception where
2266     toThrowable = Java.unsafeCoerce
2267
2268 "Prints the given value in the console."
2269 @inline
2270 print :: Show a => a -> <Proc> ()
2271 print v = printString (showForPrinting v)
2272 /*
2273 instance Show TypeRep where
2274     sb <+ (TApply (TCon "Builtin" "[]") b) =
2275         sb << "[" <+ b << "]"
2276     sb <+ (TApply (TApply (TCon "Builtin" "(,)") c1) c2) =
2277         sb << "(" <+ c1 << "," <+ c2 << ")"
2278     sb <+ (TApply (TApply (TApply (TCon "Builtin" "(,,)") c1) c2) c3) =
2279         sb << "(" <+ c1 << "," <+ c2 << "," <+ c3 << ")"
2280     sb <+ (TApply (TApply (TApply (TApply (TCon "Builtin" "(,,,)") c1) c2) c3) c4) =
2281         sb << "(" <+ c1 << "," <+ c2 << "," <+ c3 << "," <+ c4 << ")"
2282
2283     sb <+ (TCon _ name) = sb << name
2284     sb <+ (TApply a b) = sb <+ Par 1 a << " " <+ Par 2 b
2285     sb <+ (TFun a b) = sb <+ Par 1 a << " -> " <+ b
2286
2287     precedence (TCon _ _) = 0
2288     precedence (TFun _ _) = 2
2289     precedence (TApply a _) = if isSpecialType a then 0 else 1
2290       where
2291         isSpecialType (TCon "Builtin" "[]") = True
2292         isSpecialType (TCon "Builtin" "()") = True
2293         isSpecialType (TCon "Builtin" "(,)") = True
2294         isSpecialType (TCon "Builtin" "(,,)") = True
2295         isSpecialType (TCon "Builtin" "(,,,)") = True
2296         isSpecialType (TApply a _) = isSpecialType a
2297 */
2298
2299 // Type
2300
2301 @private
2302 importJava "org.simantics.scl.compiler.types.Type" where
2303     @JavaName toString
2304     showType :: Type -> String
2305
2306 importJava "org.simantics.scl.compiler.types.Types" where
2307     removeForAll :: Type -> Type
2308
2309 instance Show Type where
2310     show = showType