bundles/org.simantics.scl.runtime/scl/Prelude.scl

   1 import "JavaBuiltin" as Java
   2 import "StringBuilder" as StringBuilder
   3
   4 /** The following types and names are builtin *************
   5 data Boolean = True | False
   6 data Byte
   7 data Character
   8 data Short
   9 data Integer
  10 data Long
  11 data Float
  12 data Double
  13 data BooleanArray
  14 data ByteArray
  15 data CharacterArray
  16 data ShortArray
  17 data IntegerArray
  18 data LongArray
  19 data FloatArray
  20 data DoubleArray
  21 data Array a
  22 data String
  23 data a -> b
  24 data [a] = [] | [a] | [a,a] | [a,a,a] | ...
  25 data () = ()
  26 data (a,b) = (a,b)
  27 data (a,b,c) = (a,b,c)
  28 data Maybe a = Nothing | Just a
  29
  30 fail :: String -> a
  31
  32 data TypeRep = TCon String | TApply TypeRep TypeRep
  33 class Typeable a
  34 typeOf :: Typeable a => a -> Type
  35
  36 data Binding a
  37 class Serializable a
  38 binding :: Serializable a => Binding a
  39 ***********************************************************/
  40
  41 importJava "java.util.Arrays" where
  42     @private
  43     @JavaName toString
  44     showDoubleArray :: DoubleArray -> String
  45
  46     "Converts an array to a list."
  47     @JavaName asList
  48     arrayToList :: Array a -> [a]
  49
  50 importJava "java.util.List" where
  51     "Converts a list to an array."
  52     @JavaName toArray
  53     listToArray :: [a] -> Array a
  54
  55 instance Show DoubleArray where
  56     show = showDoubleArray
  57
  58 importJava "org.simantics.scl.runtime.Coercion" where
  59     "Converts a list of doubles to a double array."
  60     toDoubleArray :: [Double] -> DoubleArray
  61     "Converts a double array to a list of doubles."
  62     fromDoubleArray :: DoubleArray -> [Double]
  63
  64 /*
  65  * Precedences and associativity of all operators defined in Prelude
  66  */
  67
  68 infixr 10 (!)
  69 infixr 9  (.)
  70 infixr 8  (^)
  71 infixl 7  (*), (/), div, mod
  72 infixl 6  (+), (-)
  73 infixl 5  (\\), (<<), (<+)
  74 infix  4  (!=), (<), (<=), (>=), (>)
  75 infixr 3  (&&), (&<&)
  76 infixr 2  (||), orElse, morelse
  77 infixr 1  (>>=), (>>), (:=), (>=>)
  78 infixr 1  ($)
  79 infixl 1  catch
  80
  81 "Creates a constant function. `const x` defines a function that always returns `x`."
  82 @inline
  83 const :: a -> b -> a
  84 const c x = c
  85
  86 """
  87 Function application. `f $ x` is equivalent with `f x`. The function has two uses.
  88 First is to remove parentheses from deeply nested expressions:
  89
  90     f (g (h x))  ==  f $ g $ h x
  91
  92 The second use is with higher order functions:
  93
  94     map ($ parameter) functions
  95 """
  96 @macro
  97 @inline
  98 ($) :: (a -> <e> b) -> a -> <e> b
  99 f $ x = f x
 100
 101 "Transforms a function taking a pair as a parameter to a function taking two values as a parameter."
 102 @inline
 103 curry :: ((a, b) -> <e> c) -> a -> b -> <e> c
 104 curry f x y =  f (x, y)
 105
 106 "Transforms a function two values as a parameter to a function taking a pair as a parameter."
 107 @inline
 108 uncurry :: (a -> b -> <e> c) -> ((a, b) -> <e> c)
 109 uncurry f (x, y) = f x y
 110
 111 "Transforms a function taking a triple as a parameter to a function taking three values as a parameter."
 112 @inline
 113 curry3 :: ((a, b, c) -> <e> d) -> a -> b -> c -> <e> d
 114 curry3 f x y z =  f (x, y, z)
 115
 116 "Transforms a function three values as a parameter to a function taking a priple as a parameter."
 117 @inline
 118 uncurry3 :: (a -> b -> c -> <e> d) -> ((a, b, c) -> <e> d)
 119 uncurry3 f (x, y, z) = f x y z
 120
 121 "Flips the parameters of a binary function."
 122 @inline
 123 flip :: (a -> b -> <e> c) -> b -> a -> <e> c
 124 flip f x y =  f y x
 125
 126 "Swaps the order of elements of a pair (2-tuple)."
 127 swap :: (a,b) -> (b,a)
 128 swap (x,y) = (y,x)
 129
 130 /// Comparison ///
 131
 132 @inline
 133 (!=) :: a -> a -> Boolean
 134 a != b = not (a == b)
 135
 136 """
 137 The class of linearly ordered types.
 138 Method `compare` must be implemented in instances.
 139 """
 140 class Ord a where
 141     """
 142     `compare x y` returns a negative number, if `x` is smaller than `y`,
 143     a positive number, if `x` is bigger than `y` and zero if they are equal.
 144     """
 145     compare :: a -> a -> Integer
 146     compare a b = if a < b then -1 else if a > b then 1 else 0
 147
 148     "Less"
 149     (<) :: a -> a -> Boolean
 150     a < b = compare a b < 0
 151     "Less or equal"
 152     (<=) :: a -> a -> Boolean
 153     a <= b = compare a b <= 0
 154     "Greater"
 155     (>) :: a -> a -> Boolean
 156     a > b = compare a b > 0
 157     "Greater or equal"
 158     (>=) :: a -> a -> Boolean
 159     a >= b = compare a b >= 0
 160
 161     "Minimum of the parameters"
 162     min :: a -> a -> a
 163     min a b = if a < b then a else b
 164     "Maximum of the parameters"
 165     max :: a -> a -> a
 166     max a b = if a > b then a else b
 167
 168 """
 169 Combines two integers such that if the first one is non-zero, it is returned, otherwise
 170 the second-one. The second parameter is not implemented, if it is not needed.
 171
 172 The function is useful for implementing efficient recursive comparison of structures,
 173 for example:
 174
 175     compare (x1,y1,z1) (x2,y2,z2) = compare x1 x2 &<& compare y1 y2 &<& compare z1 z2
 176 """
 177 @inline
 178 (&<&) :: Integer -> (<e> Integer) -> <e> Integer
 179 a &<& b = if a == 0 then b else a
 180
 181 "Maximum over a list"
 182 @inline
 183 maximum :: Ord a => [a] -> a
 184 maximum = foldl1 max
 185
 186 "Minimum over a list"
 187 @inline
 188 minimum :: Ord a => [a] -> a
 189 minimum = foldl1 min
 190
 191 "As `maximum` but compares the elements by the given projection."
 192 maximumBy :: Ord b => (a -> <e> b) -> [a] -> <e> a
 193 maximumBy f l = snd $ foldl1 maxF $ map (\x -> (f x, x)) l
 194   where
 195     maxF a b = if fst a >= fst b then a else b
 196
 197 """
 198 As `minimum` but compares the elements by the given projection.
 199 For example
 200
 201     minimumBy snd l
 202
 203 returns a pair with the smallest second component.
 204 """
 205 minimumBy :: Ord b => (a -> <e> b) -> [a] -> <e> a
 206 minimumBy f l = snd $ foldl1 minF $ map (\x -> (f x, x)) l
 207   where
 208     minF a b = if fst a <= fst b then a else b
 209
 210 /// Functions ///
 211 /*
 212 instance Functor ((->) a) where
 213     map f g x = f (g x)
 214
 215 instance Monad ((->) a) where
 216     return v x = v
 217     (m >>= f) x = f (m x) x
 218     join f x = f x x
 219
 220 instance Category (->) where
 221     id x = x
 222     @inline
 223     (f . g) x = f (g x)
 224 */
 225 instance (Additive b) => Additive (a -> <e> b) where
 226     zero x = zero
 227     (f + g) x = f x + g x
 228
 229 instance (Ring b) => Ring (a -> <e> b) where
 230     one x = one
 231     (neg f) x = neg (f x)
 232     (f - g) x = f x - g x
 233     (f * g) x = f x * g x
 234     (fromInteger c) x = fromInteger c
 235
 236 //instance Show (a -> <e> b) where
 237 //    show f = "<function>"
 238
 239 "Appends a string to the string builder."
 240 (<<) :: StringBuilder.T -> String -> <Proc> StringBuilder.T
 241 (<<) =  StringBuilder.appendString
 242
 243 """
 244 The class of types whose elements can be converted to a string representation.
 245 Method `show` or `(<+)` must be implemented.
 246 """
 247 class Show a where
 248     "Converts a value to string."
 249     show :: a -> String
 250     "Appends the string representation of the value to the string builder."
 251     (<+) :: StringBuilder.T -> a -> <Proc> StringBuilder.T
 252     """
 253     Returns the precedence of the value. It is used to determine if parenteheses
 254     are needed around the string representation of the value. The default value is 0
 255     and means that parentheses are never added.
 256     """
 257     precedence :: a -> Integer
 258
 259     "Converts a value to a string like `show` but does not put string literals in double quotes."
 260     showForPrinting :: a -> String
 261
 262     show v = runProc (StringBuilder.toString (StringBuilder.new <+ v))
 263     showForPrinting v = show v
 264     sb <+ v = StringBuilder.appendString sb (show v)
 265     precedence v = 0
 266
 267 """
 268 `Par` data type is used to control the placement of parentheses when converting values to string.
 269 Value `Par prec val` is converted to string like `val` but parentheses are put around, if the
 270 precedence of the value is greater than `prec`.
 271 """
 272 data Par a = Par Integer a
 273
 274 instance (Show a) => Show (Par a) where
 275     sb <+ (Par outerPrec v) = if prec > outerPrec
 276                                  then sb << "(" <+ v << ")"
 277                                  else sb <+ v
 278                               where prec = precedence v
 279
 280 "Type class for parsing strings to values."
 281 class Read a where
 282     "Converts a string to a required type of value."
 283     read :: String -> a
 284 """
 285 The `Additive` class is used for types that are additive monoids. The operations
 286 must satisfy the following laws (at least approximately, when implemented for
 287 floating point numbers):
 288     (a + b) + c   = a + (b + c)
 289     a + 0 = 0 + a = a
 290 """
 291 class Additive a where
 292     """
 293     Neutral element of (+), i.e,
 294
 295         x + zero == x
 296         zero + x == x
 297     """
 298     zero :: a
 299     "Adds two objects (numbers, vectors, strings, etc.) together."
 300     (+)  :: a -> a -> a
 301     """
 302     Sum of the elements:
 303
 304         sum [e1,e2,...,eN] = e1 + e2 + ... + eN
 305
 306     Implemented usually more efficiently than with repetitive
 307     application of `(+)`.
 308     """
 309     sum  :: [a] -> a
 310     sum = foldl (+) zero
 311 /*
 312 class (Additive a) => AdditiveGroup a where
 313     neg :: a -> a
 314     (-) :: a -> a -> a
 315     x - y = x + (neg y)
 316 */
 317 """
 318 The `Ring` class is used for types that are algebraic rings. The operations
 319 must satisfy the following laws (at least approximately)
 320 in addition to the laws of Additive:
 321
 322     a + b         = b + a
 323     a - b         = a + (neg b)
 324     a - a         = 0
 325     (a * b) * c   = a * (b * c)
 326     a * 1 = 1 * a = a
 327     a * (b + c)   = a * b + a * c
 328     (a + b) * c   = a * c + b * c
 329 """
 330 class (Additive a) => Ring a where
 331     """
 332     Negation. Synonym for unary `-`.
 333     """
 334     neg :: a -> a
 335     "Subtraction"
 336     (-) :: a -> a -> a
 337     "Neutral element of multiplication"
 338     one :: a
 339     "Multiplication"
 340     (*) :: a -> a -> a
 341     "Converts an integer to a desired numeric type."
 342     fromInteger :: Integer -> a
 343     x - y = x + (neg y)
 344
 345
 346 """
 347 The `OrderedRing` class combines the Ring and Ord classes. It additionally
 348 supports absolute value function.
 349 """
 350 class (Ring a, Ord a) => OrderedRing a where
 351     "Absolute value."
 352     abs :: a -> a
 353     abs x = if x < zero then neg x else x
 354     "Converts the given number to `Integer`"
 355     toInteger :: a -> Integer
 356
 357 """
 358 The `Integer` class is used for types that represent either all integers or some
 359 range of them.
 360 """
 361 class (OrderedRing a) => Integral a where
 362     "Integer division truncated toward zero."
 363     div :: a -> a -> a
 364     "Integer remainder, satisfying ``(x `div` y)*y + (x `mod` y) = x``"
 365     mod :: a -> a -> a
 366
 367 """
 368 The `Real` class is used for types that represent some approximation of real numbers.
 369 """
 370 class (OrderedRing a) => Real a where
 371     "Division"
 372     (/) :: a -> a -> a
 373     "Exponentation"
 374     (^) :: a -> a -> a
 375     "Pi (3.141592654...)"
 376     pi  :: a
 377     "Square root"
 378     sqrt :: a -> a
 379     "Exponent function"
 380     exp :: a -> a
 381     "Natural logarithm"
 382     log :: a -> a
 383     "Sine"
 384     sin :: a -> a
 385     "Cosine"
 386     cos :: a -> a
 387     "Tangent"
 388     tan :: a -> a
 389     "Inverse sine"
 390     asin :: a -> a
 391     "Inverse cosine"
 392     acos :: a -> a
 393     "Inverse tangent."
 394     atan :: a -> a
 395     "Hyperbolic sine"
 396     sinh :: a -> a
 397     "Hyperbolic cosine"
 398     cosh :: a -> a
 399     "Hyperbolic tangent"
 400     tanh :: a -> a
 401     "Inverse hyberbolic sine"
 402     asinh :: a -> a
 403     "Inverse hyberbolic cosine"
 404     acosh :: a -> a
 405     "Inverse hyberbolic tangent"
 406     atanh :: a -> a
 407     "The largest integer not greater than the given number"
 408     floor :: a -> a
 409     "The smallest integer not smaller than the given number"
 410     ceil :: a -> a
 411     round :: a -> Long
 412     """
 413     Two parameter version of `atan`. Its value is determined by the following
 414     equations when (x,y) is a unit vector:
 415
 416         x = cos (atan2 y x)
 417         y = sin (atan2 y x)
 418
 419     When x > 0,
 420
 421         atan2 y x = atan (y/x)
 422     """
 423     atan2 :: a -> a -> a
 424     "Converts a `Double` value to a desired numeric type."
 425     fromDouble :: Double -> a
 426     "Converts the given number to `Double`"
 427     toDouble :: a -> Double
 428
 429     a ^ b = exp (b * log a)
 430
 431     sinh x = 0.5 * (exp x - exp (neg x))
 432     cosh x = 0.5 * (exp x + exp (neg x))
 433     tanh x = (e2x - 1) / (e2x + 1)
 434       where
 435         e2x = exp (2*x)
 436
 437     asinh x = log (x + sqrt (x*x + one))
 438     acosh x = log (x + sqrt (x*x - one))
 439     atanh x = 0.5 * log ((one+x)/(one-x))
 440
 441 /// Import mathematical functions ///
 442
 443 @private
 444 importJava "java.lang.Math" where
 445     @JavaName PI
 446     piDouble :: Double
 447
 448     @JavaName sin
 449     sinDouble :: Double -> Double
 450
 451     @JavaName cos
 452     cosDouble :: Double -> Double
 453
 454     @JavaName tan
 455     tanDouble :: Double -> Double
 456
 457     @JavaName asin
 458     asinDouble :: Double -> Double
 459
 460     @JavaName acos
 461     acosDouble :: Double -> Double
 462
 463     @JavaName atan
 464     atanDouble :: Double -> Double
 465
 466     @JavaName atan2
 467     atan2Double :: Double -> Double -> Double
 468
 469     @JavaName sinh
 470     sinhDouble :: Double -> Double
 471
 472     @JavaName cosh
 473     coshDouble :: Double -> Double
 474
 475     @JavaName tanh
 476     tanhDouble :: Double -> Double
 477
 478     @JavaName exp
 479     expDouble :: Double -> Double
 480
 481     @JavaName log
 482     logDouble :: Double -> Double
 483
 484     @JavaName pow
 485     powDouble :: Double -> Double -> Double
 486
 487     @JavaName sqrt
 488     sqrtDouble :: Double -> Double
 489
 490     @JavaName ceil
 491     ceilDouble :: Double -> Double
 492
 493     @JavaName floor
 494     floorDouble :: Double -> Double
 495
 496     @JavaName round
 497     roundDouble :: Double -> Long
 498
 499     @JavaName abs
 500     absInteger :: Integer -> Integer
 501
 502     @JavaName abs
 503     absLong :: Long -> Long
 504
 505     @JavaName abs
 506     absFloat :: Float -> Float
 507
 508     @JavaName abs
 509     absDouble :: Double -> Double
 510
 511     @JavaName min
 512     minInteger :: Integer -> Integer -> Integer
 513
 514     @JavaName min
 515     minLong :: Long -> Long -> Long
 516
 517     @JavaName min
 518     minFloat :: Float -> Float -> Float
 519
 520     @JavaName min
 521     minDouble :: Double -> Double -> Double
 522
 523     @JavaName max
 524     maxInteger :: Integer -> Integer -> Integer
 525
 526     @JavaName max
 527     maxLong :: Long -> Long -> Long
 528
 529     @JavaName max
 530     maxFloat :: Float -> Float -> Float
 531
 532     @JavaName max
 533     maxDouble :: Double -> Double -> Double
 534
 535 /// Integer ///
 536
 537 @private
 538 importJava "java.lang.Byte" where
 539     @JavaName toString
 540     showByte :: Byte -> String
 541
 542     @JavaName parseByte
 543     readByte :: String -> Byte
 544
 545 instance Ord Byte where
 546     (<) = Java.bcmplt
 547     (<=) = Java.bcmple
 548     (>) = Java.bcmpgt
 549     (>=) = Java.bcmpge
 550
 551 instance Additive Byte where
 552     zero = Java.i2b Java.iconst_0
 553     (+) = Java.badd
 554
 555 instance Ring Byte where
 556     neg = Java.bneg
 557     (-) = Java.bsub
 558     one = Java.i2b Java.iconst_1
 559     (*) = Java.bmul
 560     fromInteger = Java.i2b
 561
 562 instance Show Byte where
 563     show = showByte
 564     precedence v = if v >= 0 then 0 else 100
 565
 566 instance Read Byte where
 567     read = readByte
 568
 569
 570 @private
 571 importJava "java.lang.Short" where
 572     @JavaName toString
 573     showShort :: Short -> String
 574
 575     @JavaName parseShort
 576     readShort :: String -> Short
 577
 578 instance Ord Short where
 579     (<) = Java.scmplt
 580     (<=) = Java.scmple
 581     (>) = Java.scmpgt
 582     (>=) = Java.scmpge
 583
 584 instance Additive Short where
 585     zero = Java.sconst_0
 586     (+) = Java.sadd
 587
 588 instance Ring Short where
 589     neg = Java.sneg
 590     (-) = Java.ssub
 591     one = Java.sconst_1
 592     (*) = Java.smul
 593     fromInteger = Java.i2s
 594
 595 instance Show Short where
 596     show = showShort
 597     precedence v = if v >= 0 then 0 else 100
 598
 599 instance Read Short where
 600     read = readShort
 601
 602 /// Integer ///
 603
 604 @private
 605 importJava "java.lang.Integer" where
 606     @JavaName toString
 607     showInteger :: Integer -> String
 608
 609     @JavaName parseInt
 610     readInteger :: String -> Integer
 611
 612 instance Ord Integer where
 613     (<) = Java.icmplt
 614     (<=) = Java.icmple
 615     (>) = Java.icmpgt
 616     (>=) = Java.icmpge
 617
 618 instance Additive Integer where
 619     zero = Java.iconst_0
 620     (+) = Java.iadd
 621
 622 instance Ring Integer where
 623     neg = Java.ineg
 624     (-) = Java.isub
 625     one = Java.iconst_1
 626     (*) = Java.imul
 627     fromInteger x = x
 628
 629 instance OrderedRing Integer where
 630     abs = absInteger
 631     toInteger x = x
 632
 633 instance Integral Integer where
 634     div = Java.idiv
 635     mod = Java.irem
 636
 637 instance Show Integer where
 638     show = showInteger
 639     precedence v = if v >= 0 then 0 else 100
 640
 641 instance Read Integer where
 642     read = readInteger
 643
 644 /// Long ///
 645
 646 @private
 647 importJava "java.lang.Long" where
 648     @JavaName toString
 649     showLong :: Long -> String
 650
 651     @JavaName parseLong
 652     readLong :: String -> Long
 653
 654 instance Ord Long where
 655     (<) = Java.lcmplt
 656     (<=) = Java.lcmple
 657     (>) = Java.lcmpgt
 658     (>=) = Java.lcmpge
 659
 660 instance Additive Long where
 661     zero = Java.lconst_0
 662     (+) = Java.ladd
 663
 664 instance Ring Long where
 665     neg = Java.lneg
 666     (-) = Java.lsub
 667     one = Java.lconst_1
 668     (*) = Java.lmul
 669     fromInteger = Java.i2l
 670
 671 instance OrderedRing Long where
 672     abs = absLong
 673     toInteger = Java.l2i
 674
 675 instance Integral Long where
 676     div = Java.ldiv
 677     mod = Java.lrem
 678
 679 instance Show Long where
 680     show = showLong
 681     precedence v = if v >= 0 then 0 else 100
 682
 683 instance Read Long where
 684     read = readLong
 685
 686 /// Float ///
 687
 688 importJava "java.lang.Float" where
 689     @private
 690     @JavaName compare
 691     compareFloat :: Float -> Float -> Integer
 692
 693     @private
 694     @JavaName toString
 695     showFloat :: Float -> String
 696
 697     @private
 698     @JavaName parseFloat
 699     readFloat :: String -> Float
 700
 701     "Converts 32-bit floating point number to a 32-bit integer with the same byte level representation."
 702     floatToIntBits :: Float -> Integer
 703
 704 instance Ord Float where
 705     compare = compareFloat
 706     (<) = Java.fcmplt
 707     (<=) = Java.fcmple
 708     (>) = Java.fcmpgt
 709     (>=) = Java.fcmpge
 710
 711 instance Additive Float where
 712     zero = Java.fconst_0
 713     (+) = Java.fadd
 714
 715 instance Ring Float where
 716     neg = Java.fneg
 717     (-) = Java.fsub
 718     one = Java.fconst_1
 719     (*) = Java.fmul
 720     fromInteger = Java.i2f
 721
 722 instance OrderedRing Float where
 723     abs = absFloat
 724     toInteger = Java.f2i
 725
 726 instance Real Float where
 727     (/) = Java.fdiv
 728     x ^ y = Java.d2f (powDouble (Java.f2d x) (Java.f2d y))
 729     pi = fromDouble piDouble
 730     sqrt = Java.d2f . sqrtDouble . Java.f2d
 731     exp = Java.d2f . expDouble . Java.f2d
 732     log = Java.d2f . logDouble . Java.f2d
 733     sin = Java.d2f . sinDouble . Java.f2d
 734     cos = Java.d2f . cosDouble . Java.f2d
 735     tan = Java.d2f . tanDouble . Java.f2d
 736     asin = Java.d2f . asinDouble . Java.f2d
 737     acos = Java.d2f . acosDouble . Java.f2d
 738     atan = Java.d2f . atanDouble . Java.f2d
 739     sinh = Java.d2f . sinhDouble . Java.f2d
 740     cosh = Java.d2f . coshDouble . Java.f2d
 741     tanh = Java.d2f . tanhDouble . Java.f2d
 742     floor = Java.d2f . floorDouble . Java.f2d
 743     ceil = Java.d2f . ceilDouble . Java.f2d
 744     atan2 y x = Java.d2f (atan2Double (Java.f2d y) (Java.f2d x))
 745     round = roundDouble . Java.f2d
 746     fromDouble = Java.d2f
 747     toDouble = Java.f2d
 748
 749 instance Show Float where
 750     show = showFloat
 751     precedence v = if v >= 0 then 0 else 100
 752
 753 instance Read Float where
 754     read = readFloat
 755
 756 /// Double ///
 757
 758 importJava "java.lang.Double" where
 759     @private
 760     @JavaName compare
 761     compareDouble :: Double -> Double -> Integer
 762
 763     @private
 764     @JavaName toString
 765     showDouble :: Double -> String
 766
 767     @private
 768     @JavaName parseDouble
 769     readDouble :: String -> Double
 770
 771     "Converts 64-bit floating point number to a 64-bit integer with the same byte level representation."
 772     doubleToLongBits :: Double -> Long
 773
 774     isFinite :: Double -> Boolean
 775     isNaN :: Double -> Boolean
 776     isInfinite :: Double -> Boolean
 777
 778 instance Ord Double where
 779     compare = compareDouble
 780     (<) = Java.dcmplt
 781     (<=) = Java.dcmple
 782     (>) = Java.dcmpgt
 783     (>=) = Java.dcmpge
 784
 785 instance Additive Double where
 786     zero = Java.dconst_0
 787     (+) = Java.dadd
 788
 789 instance Ring Double where
 790     neg = Java.dneg
 791     (-) = Java.dsub
 792     one = Java.dconst_1
 793     (*) = Java.dmul
 794     fromInteger = Java.i2d
 795
 796 instance OrderedRing Double where
 797     abs = absDouble
 798     toInteger = Java.d2i
 799
 800 instance Real Double where
 801     (/) = Java.ddiv
 802     (^) = powDouble
 803     pi = piDouble
 804     sqrt = sqrtDouble
 805     exp = expDouble
 806     log = logDouble
 807     sin = sinDouble
 808     cos = cosDouble
 809     tan = tanDouble
 810     asin = asinDouble
 811     acos = acosDouble
 812     atan = atanDouble
 813     sinh = sinhDouble
 814     cosh = coshDouble
 815     tanh = tanhDouble
 816     floor = floorDouble
 817     ceil = ceilDouble
 818     atan2 = atan2Double
 819     round = roundDouble
 820     fromDouble x = x
 821     toDouble x = x
 822
 823 instance Show Double where
 824     show = showDouble
 825     precedence v = if v >= 0 then 0 else 100
 826
 827 instance Read Double where
 828     read = readDouble
 829
 830 /// Character ///
 831
 832 importJava "java.lang.Character" where
 833     @JavaName toString
 834     showCharacter :: Character -> String
 835
 836     "Returns true, if the given character is a letter."
 837     isLetter :: Character -> Boolean
 838
 839     "Returns true, if the given character is a digit."
 840     isDigit :: Character -> Boolean
 841
 842 instance Ord Character where
 843     (<) = Java.ccmplt
 844     (<=) = Java.ccmple
 845     (>) = Java.ccmpgt
 846     (>=) = Java.ccmpge
 847
 848 instance Show Character where
 849     sb <+ c = sb << "'" << showCharacter c << "'"
 850
 851 "Adds a given integer to the character code."
 852 addChar :: Character -> Integer -> Character
 853 addChar = Java.cadd
 854
 855 "Subtracts a given integer from the character code."
 856 subChar :: Character -> Character -> Integer
 857 subChar = Java.csub
 858
 859 /// Functor ///
 860
 861 """
 862 The `Functor` class is used for types that can be mapped over. Instances of `Functor` should satisfy the following laws:
 863
 864     fmap id  ==  id
 865     fmap (f . g)  ==  fmap f . fmap g
 866 """
 867 class Functor f where
 868     "Lifts a pure function to the given functor."
 869     fmap :: (a -> b) -> f a -> f b
 870 /*
 871 class CoFunctor f where
 872     comap :: (a -> b) -> f b -> f a
 873 */
 874 /// Applicative ///
 875 /*
 876 class (Functor f) => Applicative f where
 877     return :: a -> f a
 878     (<*>) :: f (a -> b) -> f a -> f b
 879     (*>) :: f a -> f b -> f b
 880     (<*) :: f a -> f b -> f a
 881
 882     u *> v = pure (const id) <*> u <*> v
 883     u <* v = pure const <*> u <*> v
 884     fmap f x = pure f <*> x
 885 */
 886 /// Monad ///
 887
 888 """
 889 The `Monad` class defines the basic operations over a monad, a concept from a branch of mathematics known as category theory.
 890 From the perspective of a SCL programmer, however, it is best to think of a monad as an abstract datatype of actions.
 891 SCL's `mdo expressions provide a convenient syntax for writing monadic expressions.
 892
 893 Instances of `Monad` should satisfy the following laws:
 894
 895     return a >>= k  ==  k a
 896     m >>= return  ==  m
 897     m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 898     fmap f xs  ==  xs >>= return . f
 899 """
 900 class (Functor m) => Monad m where
 901     "Inject a value into the monadic type."
 902     return :: a -> m a
 903     "Sequentially compose two actions, passing any value produced by the first as an argument to the second."
 904     (>>=) :: m a -> (a -> m b) -> m b
 905     """
 906     The join function is the conventional monad join operator. It removes one level of monadic
 907     structure.
 908
 909     For lists, `join` concatenates a list of lists:
 910
 911         join [[1,2], [3,4]] = [1, 2, 3, 4]
 912     """
 913     join :: m (m a) -> m a
 914     join m = m >>= id
 915
 916 """
 917 Sequentially compose two actions, discarding any value produced by the first, like sequencing operators
 918 (such as the semicolon) in imperative languages."
 919 """
 920 @macro
 921 (>>) :: Monad m => m a -> m b -> m b
 922 a >> b = a >>= (\_ -> b)
 923
 924 "Left-to-right Kleisli composition of monads."
 925 (>=>) :: Monad m => (a -> m b) -> (b -> m c) -> (a -> m c)
 926 (f >=> g) x = (f x) >>= g
 927
 928 "While loop. `while cond body` executes the `body` while the `cond` is true."
 929 @inline
 930 while :: (<e> Boolean) -> (<e> a) -> <e> ()
 931 while cond body = loop ()
 932   where loop _ = if cond
 933                  then do body ; loop ()
 934                  else ()
 935
 936 """
 937 Sequences the given monadic value infinitely:
 938
 939     repeatForever m = m >> m >> m >> ...
 940 """
 941 repeatForever m = m >> repeatForever m
 942
 943 replicateM :: Monad m => Integer -> m a -> m [a]
 944 replicateM count m = loop count emptyList
 945   where
 946     loop count l | count <= 0 = return l
 947                  | otherwise  = mdo
 948                      v <- m
 949                      loop (count-1) (addList l v)
 950
 951 replicateM_ :: Monad m => Integer -> m a -> m ()
 952 replicateM_ count m | count <= 0 = return ()
 953                     | otherwise  = m >> replicateM_ (count-1) m
 954
 955 /// MonadZero ///
 956
 957 """
 958 A class of monads with zero element satisfying
 959
 960     mzero >>= f = mzero
 961 """
 962 class (Monad m) => MonadZero m where
 963     mzero :: m a
 964
 965 "Injects a boolean test to a type beloning to `MonadZero`."
 966 guard :: MonadZero m => Boolean -> m ()
 967 guard True = return ()
 968 guard False = mzero
 969
 970 /// MonadPlus ///
 971
 972 """
 973 A class of monads with associative binary operator `mplus` satisfying the following laws:
 974
 975     mplus mzero b = b
 976     mplus a mzero = a
 977     mplus (mplus a b) c = mplus a (mplus b c)
 978     mplus a b >>= k = mplus (a >>= k) (b >>= k)
 979 """
 980 class (MonadZero m) => MonadPlus m where
 981     mplus :: m a -> m a -> m a
 982
 983 /// MonadOr ///
 984
 985 """
 986 A class of monads with associative binary operator `morelse` satisfying the following laws:
 987
 988     morelse mzero b = b
 989     morelse a mzero = a
 990     morelse (morelse a b) c = morelse a (morelse b c)
 991     morelse (return a) b = return a
 992 """
 993 class (MonadZero m) => MonadOr m where
 994     morelse :: m a -> m a -> m a
 995
 996 /// FunctorE ///
 997
 998 """
 999 A class of types that can be mapped over with effectful mapping functions.
1000 """
1001 class (Functor f) => FunctorE f where
1002     """
1003     Applies the function to all elements of the container and
1004     returns the similarly shaped container with the results:
1005
1006     For lists,
1007
1008         map f [e1, e2, ..., eN] = [f e1, f e2, ..., f eN]
1009
1010     for example
1011
1012         map (*2) [1..5] = [2, 4, 6, 8, 10]
1013     """
1014     map :: (a -> <e> b) -> f a -> <e> (f b)
1015     "Calls the given function with all elements of the given container."
1016     iter :: (a -> <e> b) -> f a -> <e> ()
1017     "Calls the given function with all elements of the given container giving also the index of the element as a parameter."
1018     iterI :: (Integer -> a -> <e> b) -> f a -> <e> ()
1019
1020 "Iterates the elements of the given collection. Same as `iter` but parameters flipped."
1021 for :: FunctorE f => f a -> (a -> <e> b) -> <e> ()
1022 @macro
1023 for l f = iter f l
1024
1025 "Iterates the elements of the given collection providing also the indices of the elements. Same as `iterI` but parameters flipped."
1026 forI :: FunctorE f => f a -> (Integer -> a -> <e> b) -> <e> ()
1027 @macro
1028 forI l f = iterI f l
1029
1030 "`forN n f` calls `f` for all integers `0`, ..., `n-1`"
1031 @inline
1032 forN :: Integer -> (Integer -> <e> b) -> <e> ()
1033 forN n f = loop 0
1034   where
1035     loop i = if i < n
1036              then do f i ; loop (i+1)
1037              else ()
1038
1039 @inline
1040 mapI :: (Integer -> a -> <e> b) -> [a] -> <e> [b]
1041 mapI f l = build (\empty cons -> let
1042     len = length l
1043     loop i accum = if i < len
1044                    then loop (i+1) (cons accum (f i (l!i)))
1045                    else accum
1046   in loop 0 empty)
1047
1048 """
1049 `mapMaybe` combines `map` and `filter` functions.
1050 It applies the given function to every element of the input list. If the result
1051 is `Just x`, then `x` is added to the resulting list.
1052
1053     mapMaybe f lst = [y | x <- lst, Just y = f x]
1054 """
1055 @inline
1056 mapMaybe :: (a -> <e> Maybe b) -> [a] -> <e> [b]
1057 mapMaybe f l = build (\empty cons -> foldl (\cur x -> match f x with Just v -> cons cur v ; _ -> cur) empty l)
1058
1059 """
1060 Applies the given function to all elements of the list. Produces two lists: the first contains all elements `x`
1061 for which the function returned `Left x` and the second list contains all elements `y` for which the function
1062 returned `Right y`.
1063 """
1064 mapEither :: (a -> <e> Either b c) -> [a] -> <e> ([b], [c])
1065 mapEither f list = runProc do
1066     l = newArrayList
1067     r = newArrayList
1068     for list (\x -> match f x with
1069         Left v -> addArrayList l v
1070         Right v -> addArrayList r v)
1071     (Java.unsafeCoerce l, Java.unsafeCoerce r)
1072
1073 "`replicate n v` returns a list of length `n` such that each element is a copy of `v`."
1074 @inline
1075 replicate :: Integer -> a -> [a]
1076 replicate n v = build (\empty cons ->
1077     let aux 0 l = l
1078         aux i l = aux (i-1) (cons l v)
1079     in aux n empty
1080     )
1081
1082 /// FunctorM ///
1083
1084 class (Functor f) => FunctorM f where
1085     "`mapM f` is equivalent to `sequence . map f`."
1086     mapM :: Monad m => (a -> m b) -> f a -> m (f b)
1087     "Evaluate each action in the sequence from left to right, and collect the results."
1088     sequence :: Monad m => f (m a) -> m (f a)
1089     mapM f l = sequence (fmap f l)
1090
1091 /// MonadE ///
1092
1093 class (FunctorE m, Monad m) => MonadE m where
1094     bindE :: m a -> (a -> <e> m b) -> <e> m b
1095
1096 instance MonadE Maybe where
1097     bindE Nothing  _ = Nothing
1098     bindE (Just v) f = f v
1099
1100 instance MonadE (Either a) where
1101     bindE (Left v)  _ = Left v
1102     bindE (Right v) f = f v
1103
1104 instance MonadE [] where
1105     bindE l f = concatMap f l
1106
1107 /// Category ///
1108
1109 "Identity function."
1110 id :: a -> a
1111 id x = x
1112
1113 """
1114 Ignores the given value. This function is used in a situation where a function returns
1115 a value in a context where the value is not expected.
1116 """
1117 @inline
1118 ignore :: a -> ()
1119 ignore _ = ()
1120
1121 @inline
1122 ignoreM :: a -> Maybe b
1123 ignoreM _ = Nothing
1124
1125 """
1126 Composes two functions
1127     (f . g) x = f (g x)
1128 """
1129 (.) :: (b -> <e> c) -> (a -> <e> b) -> (a -> <e> c)
1130 (f . g) x = f (g x)
1131
1132 /// Sequence ///
1133
1134 "A type class for sequences. All sequences must support indexing by integers."
1135 class /*(Additive a) =>*/ Sequence a where
1136     "Length of the sequence"
1137     length :: a -> Integer
1138     "`take n s` returns the first `n` elements of the sequence `s`."
1139     take :: Integer -> a -> a
1140     "`drop n s` removes the first `n` elements of the sequence `s`."
1141     drop :: Integer -> a -> a
1142     """
1143     `sub s begin end` returns a subsequence of `s` starting from
1144     index `begin` and ending just before index `end`.
1145     """
1146     sub :: a -> Integer -> Integer -> a
1147
1148     take n v = sub v 0 (min n (length v))
1149     drop n v = sub v (min n len) len
1150       where
1151         len = length v
1152
1153 instance Sequence [a] where
1154     length = lengthList
1155     sub = subList
1156
1157 instance Sequence String where
1158     length = lengthString
1159     sub = subString
1160
1161 class IndexedSequence f where
1162     "`seq ! i` returns the `i`th element of the sequence `seq`. Indexing starts from zero."
1163     (!) :: f a -> Integer -> a
1164
1165 instance IndexedSequence [] where
1166     (!) = getList
1167
1168 /// Boolean ///
1169
1170 """
1171 Equivalent to the boolean value `True`. The value is meant to be used in
1172 guard patterns:
1173
1174     min a b | a < b     = a
1175             | otherwise = b
1176 """
1177 @inline
1178 otherwise :: Boolean
1179 otherwise = True
1180
1181 instance Ord Boolean where
1182     compare False False = 0
1183     compare False True  = neg 1
1184     compare True  False = 1
1185     compare True  True  = 0
1186
1187 instance Show Boolean where
1188     show True = "True"
1189     show False = "False"
1190
1191 """
1192 Boolean conjunction (and). The function is a macro that evaluates the second parameter
1193 only if the first parameter is `True`.
1194
1195 <table>
1196 <tr><th>a</th><th>b</th><th>a && b</th></tr>
1197 <tr><td>True</td><td>True</td><td>True</td></tr>
1198 <tr><td>True</td><td>False</td><td>False</td></tr>
1199 <tr><td>False</td><td>not evaluated</td><td>False</td></tr>
1200 </table>
1201 """
1202 @macro
1203 (&&) :: Boolean -> Boolean ->  Boolean
1204 a && b = if a then b else False
1205
1206 """
1207 Boolean disjunction (or). The function is a macro that evaluates the second parameter
1208 only if the first parameter is `False`.
1209
1210 <table>
1211 <tr><th>a</th><th>b</th><th>a || b</th></tr>
1212 <tr><td>True</td><td>not evaluated</td><td>True</td></tr>
1213 <tr><td>False</td><td>True</td><td>True</td></tr>
1214 <tr><td>False</td><td>False</td><td>False</td></tr>
1215 </table>
1216 """
1217 @macro
1218 (||) :: Boolean -> Boolean -> Boolean
1219 a || b = if a then True else b
1220
1221 "Boolean negation"
1222 @inline
1223 not a = if a then False else True
1224
1225 /// Maybe ///
1226
1227 //data Maybe a = Nothing | Just a
1228
1229 "Given `Just x` this function returns `x`. If the parameter is `Nothing`, the function raises an exception."
1230 fromJust :: Maybe a -> a
1231 fromJust (Just a) = a
1232
1233 deriving instance (Ord a) => Ord (Maybe a)
1234 deriving instance (Show a) => Show (Maybe a)
1235
1236 instance Functor Maybe where
1237     fmap _ Nothing  = Nothing
1238     fmap f (Just x) = Just (f x)
1239
1240 instance FunctorE Maybe where
1241     map _ Nothing  = Nothing
1242     map f (Just x) = Just (f x)
1243
1244     iter _ Nothing = ()
1245     iter f (Just x) = ignore (f x)
1246
1247     iterI _ Nothing = ()
1248     iterI f (Just x) = ignore (f 0 x)
1249
1250 instance Monad Maybe where
1251     return x = Just x
1252
1253     @inline
1254     Nothing >>= _ = Nothing
1255     Just x  >>= f = f x
1256
1257     @inline
1258     join Nothing  = Nothing
1259     join (Just x) = x
1260
1261 instance MonadZero Maybe where
1262     mzero = Nothing
1263
1264 instance MonadOr Maybe where
1265     morelse a@(Just _) _ = a
1266     morelse _ b = b
1267
1268 "`execJust v f` executes the function `f` with parameter value `x`, if `v=Just x`. If `v=Nothing`, the function does nothing."
1269 @inline
1270 execJust :: Maybe a -> (a -> <e> b) -> <e> ()
1271 execJust maybeValue procedure = match maybeValue with
1272     Just v -> ignore $ procedure v
1273     _ -> ()
1274
1275 "`fromMaybe def v` returns `def` if `v=Nothing` and `x` if `v=Just x`."
1276 @inline
1277 fromMaybe :: a -> Maybe a -> a
1278 fromMaybe default maybeValue = match maybeValue with
1279     Just v -> v
1280     _ -> default
1281
1282
1283 """
1284 Provides a default value if the first parameter is Nothing.
1285 The default value is evaluated only if needed. The function
1286 can be used as an operator and is right associative so that
1287 the following is possible:
1288
1289     tryWithTheFirstMethod
1290         `orElse` tryWithTheSecondMethod
1291         `orElse` fail "Didn't succeed."
1292 """
1293 @inline
1294 orElse :: Maybe a -> (<e> a) -> <e> a
1295 orElse (Just x) _   = x
1296 orElse Nothing  def = def
1297
1298 /// Either ///
1299
1300 """
1301 The Either type represents values with two possibilities: a value of type `Either a b` is either `Left a` or `Right b`.
1302
1303 The `Either` type is sometimes used to represent a value which is either correct or an error; by convention, the `Left` constructor
1304 is used to hold an error value and the `Right` constructor is used to hold a correct value (mnemonic: "right" also means "correct").
1305 """
1306 @JavaType "org.simantics.scl.runtime.either.Either"
1307 data Either a b =
1308     @JavaType "org.simantics.scl.runtime.either.Left"
1309     @FieldNames [value]
1310     Left a
1311   | @JavaType "org.simantics.scl.runtime.either.Right"
1312     @FieldNames [value]
1313     Right b
1314
1315 deriving instance (Ord a, Ord b) => Ord (Either a b)
1316 deriving instance (Show a, Show b) => Show (Either a b)
1317
1318 instance Functor (Either a) where
1319     fmap _ (Left x)  = Left x
1320     fmap f (Right y) = Right (f y)
1321
1322 instance FunctorE (Either a) where
1323     map _ (Left x)  = Left x
1324     map f (Right y) = Right (f y)
1325
1326     iter _ (Left x) = ()
1327     iter f (Right y) = ignore (f y)
1328
1329     iterI _ (Left x) = ()
1330     iterI f (Right y) = ignore (f 0 y)
1331
1332 instance Monad (Either b) where
1333     return y = Right y
1334
1335     Left x  >>= _ = Left x
1336     Right y >>= f = f y
1337
1338     join (Left x)  = Left x
1339     join (Right y) = y
1340
1341 /// String ///
1342
1343 importJava "java.lang.String" where
1344     @private
1345     @JavaName "concat"
1346     concatString :: String -> String -> String
1347     @private
1348     @JavaName "compareTo"
1349     compareString :: String -> String -> Integer
1350     @private
1351     @JavaName "length"
1352     lengthString :: String -> Integer
1353
1354     """
1355     `replaceString original pattern replacement` replaces all occurrences of `pattern` in the string by `replacement`.
1356     """
1357     @JavaName replace
1358     replaceString :: String -> String -> String -> String
1359
1360     @private
1361     @JavaName split
1362     splitString_ :: String -> String -> Array String
1363
1364     """
1365     `indexOf string s` finds the first occurrence of `s` from `string` and returns its index.
1366     If the `s` does not occur in the string, return `-1`."
1367     """
1368     @JavaName indexOf
1369     indexOf :: String -> String -> Integer
1370
1371     "Works like `indexOf` but starts searching from the given index instead of the beginning of the string."
1372     @JavaName indexOf
1373     indexOfStartingFrom :: String -> String -> Integer -> Integer
1374
1375     "Works like `indexOf` but returns the index of the last occurrence."
1376     @JavaName lastIndexOf
1377     lastIndexOf :: String -> String -> Integer
1378
1379     "Works like `lastIndexOf` but starts searching from the given index instead of the end of the string."
1380     @JavaName lastIndexOf
1381     lastIndexOfStartingFrom :: String -> String -> Integer -> Integer
1382
1383     @private
1384     @JavaName substring
1385     subString :: String -> Integer -> Integer -> String
1386
1387     """
1388     `regionMatches str1 offset1 str2 offset2 len` tests whether
1389     `sub str1 offset1 (offset1+len) == sub str2 offset2 (offset2+len)`.
1390     """
1391     regionMatches :: String -> Integer -> String -> Integer -> Integer -> Boolean
1392
1393     "`startsWith string prefix` returns true if the string begins with the given prefix."
1394     startsWith :: String -> String -> Boolean
1395
1396     "`endsWith string suffix` returns true if the string ends with the given prefix."
1397     endsWith :: String -> String -> Boolean
1398
1399     "Removes leading and trailing whitespace from the string."
1400     trim :: String -> String
1401
1402     "`contains string s` returns true if `string` contains `s` as a substring."
1403     contains :: String -> String -> Boolean
1404
1405     "`charAt string i` returns the `i`th character of the string."
1406     charAt :: String -> Integer -> Character
1407
1408     "Converts all letters of the string to lower case."
1409     toLowerCase :: String -> String
1410     "Converts all letters of the string to upper case."
1411     toUpperCase :: String -> String
1412
1413     "Creates a string from a vector of characters."
1414     @JavaName "<init>"
1415     string :: Vector Character -> String
1416
1417 instance Ord String where
1418     compare = compareString
1419
1420 instance Additive String where
1421     zero = ""
1422     (+) = concatString
1423     sum ss = runProc (StringBuilder.toString $ foldl StringBuilder.appendString StringBuilder.new ss)
1424
1425 @private
1426 importJava "org.simantics.scl.runtime.string.StringEscape" where
1427     appendEscapedString :: StringBuilder.T -> String -> <Proc> StringBuilder.T
1428
1429 instance Show String where
1430     showForPrinting = id
1431     sb <+ v = (appendEscapedString (sb << "\"") v) << "\""
1432
1433 instance Read String where
1434     read str = str
1435
1436 @deprecated "Instead of 'splitString text pattern', write 'split pattern text' (note change in the parameter order)."
1437 "`splitString text pattern` splits the string into a list of string where the parts are sepratated in the original list by the given pattern."
1438 splitString :: String -> String -> [String]
1439 splitString source pattern = arrayToList $ splitString_ source pattern
1440
1441 """
1442 `split pattern text` splits `text` around matches of the given regular expression `pattern`.
1443
1444 This function works as if by invoking the two-argument split method with the given expression and a limit argument of zero. Trailing empty strings are therefore not included in the resulting array.
1445
1446 The string "boo:and:foo", for example, yields the following results with these expressions:
1447
1448     Regex   Result
1449     :       { "boo", "and", "foo" }
1450     o       { "b", "", ":and:f" }
1451 """
1452 split :: String -> String -> [String]
1453 split pattern text = arrayToList $ splitString_ text pattern
1454
1455 /// Tuple0 ///
1456
1457 instance Ord () where
1458     compare () () = 0
1459
1460 instance Additive () where
1461     zero = ()
1462     () + () = ()
1463
1464 instance Show () where
1465     show () = "()"
1466
1467 /// Tuple2 ///
1468
1469 "Gives the first element of a pair."
1470 @inline
1471 fst :: (a,b) -> a
1472 fst (x,y) = x
1473
1474 "Gives the second element of a pair."
1475 @inline
1476 snd :: (a,b) -> b
1477 snd (x,y) = y
1478
1479 instance (Ord a, Ord b) => Ord (a, b) where
1480     compare (a0, b0) (a1, b1) = compare a0 a1 &<& compare b0 b1
1481
1482 instance (Additive a, Additive b) => Additive (a, b) where
1483     zero = (zero, zero)
1484     (a0, b0) + (a1, b1) = (a0+a1, b0+b1)
1485
1486 instance Functor ((,) a) where
1487     fmap f (a,b) = (a, f b)
1488
1489 instance (Show a, Show b) => Show (a, b) where
1490     sb <+ (x, y) = sb << "(" <+ x << ", " <+ y << ")"
1491
1492 /// Tuple3 ///
1493
1494 instance (Ord a, Ord b, Ord c) => Ord (a, b, c) where
1495     compare (a0, b0, c0) (a1, b1, c1) = compare a0 a1 &<& compare b0 b1 &<& compare c0 c1
1496
1497 instance (Additive a, Additive b, Additive c) => Additive (a, b, c) where
1498     zero = (zero, zero, zero)
1499     (a0, b0, c0) + (a1, b1, c1) = (a0+a1, b0+b1, c0+c1)
1500
1501 instance Functor ((,,) a b) where
1502     fmap f (a,b,c) = (a, b, f c)
1503
1504 instance (Show a, Show b, Show c) => Show (a, b, c) where
1505     sb <+ (x, y, z) = sb << "(" <+ x << ", " <+ y << ", " <+ z << ")"
1506
1507 /// Tuple4 ///
1508
1509 instance (Ord a, Ord b, Ord c, Ord d) => Ord (a, b, c, d) where
1510     compare (a0, b0, c0, d0) (a1, b1, c1, d1) =
1511         compare a0 a1 &<& compare b0 b1 &<& compare c0 c1 &<& compare d0 d1
1512
1513 instance (Additive a, Additive b, Additive c, Additive d) => Additive (a, b, c, d) where
1514     zero = (zero, zero, zero, zero)
1515     (a0, b0, c0, d0) + (a1, b1, c1, d1) = (a0+a1, b0+b1, c0+c1, d0+d1)
1516
1517 instance Functor ((,,,) a b c) where
1518     fmap f (a,b,c,d) = (a, b, c, f d)
1519
1520 instance (Show a, Show b, Show c, Show d) => Show (a, b, c, d) where
1521     sb <+ (x, y, z, w) = sb << "(" <+ x << ", " <+ y << ", " <+ z << ", " <+ w << ")"
1522
1523 /// Tuple5 ///
1524
1525 instance (Ord a, Ord b, Ord c, Ord d, Ord e) => Ord (a, b, c, d, e) where
1526     compare (a0, b0, c0, d0, e0) (a1, b1, c1, d1, e1) =
1527         compare a0 a1 &<& compare b0 b1 &<& compare c0 c1 &<& compare d0 d1 &<& compare e0 e1
1528
1529 instance (Additive a, Additive b, Additive c, Additive d, Additive e) => Additive (a, b, c, d, e) where
1530     zero = (zero, zero, zero, zero, zero)
1531     (a0, b0, c0, d0, e0) + (a1, b1, c1, d1, e1) = (a0+a1, b0+b1, c0+c1, d0+d1, e0+e1)
1532
1533 instance Functor ((,,,,) a b c d) where
1534     fmap f (a,b,c,d,e) = (a, b, c, d, f e)
1535
1536 /// Lists ///
1537
1538 instance (Ord a) => Ord [a] where
1539     compare a b = loop 0
1540       where
1541         lA = length a
1542         lB = length b
1543         loop i = if i >= lA
1544                  then (if i >= lB then 0 else -1)
1545                  else if i >= lB
1546                  then 1
1547                  else compare (a!i) (b!i) &<& loop (i+1)
1548
1549 instance Functor [] where
1550     fmap = mapList
1551
1552 instance FunctorE [] where
1553     map = mapEList
1554     iter = iterList
1555     iterI = iterIList
1556
1557 instance Monad [] where
1558     return x = singletonList x
1559     l >>= f  = concatMap f l
1560     join l   = l >>= id
1561
1562 instance MonadZero [] where
1563     mzero = emptyList
1564
1565 instance MonadPlus [] where
1566     mplus = appendList
1567
1568 instance Additive [a] where
1569     zero = emptyList
1570     (+) = appendList
1571
1572 instance FunctorM [] where
1573     sequence = foldl (\m mel -> m >>= \l -> mel >>= \el -> return (addList l el)) (return emptyList)
1574     mapM f l = sequence (map f l)
1575
1576 "Appends the string representations of all elements of the list to the string builder and separates the values with the given separator."
1577 printWithSeparator :: Show a => StringBuilder.T -> String -> [a] -> <Proc> StringBuilder.T
1578 printWithSeparator sb sep l = loop 0
1579   where
1580     len = length l
1581     loop i = if i >= len then sb
1582              else do
1583                  (if i==0 then sb else sb << sep) <+ l!i
1584                  loop (i+1)
1585
1586 """
1587 Joins the string representations of the list of values with the given separator.
1588
1589 See [intercalate](#intercalate) for an alternative that works with Strings
1590 and doesn't escape its arguments.
1591 """
1592 joinWithSeparator :: Show a => String -> [a] -> String
1593 joinWithSeparator separator values = runProc (
1594     StringBuilder.toString $ printWithSeparator StringBuilder.new separator values)
1595
1596
1597 """
1598 The intercalate function takes a String and a list of Strings
1599 and concatenates the list after interspersing the first argument
1600 between each element of the list.
1601
1602 See also more generic [joinWithSeparator](#joinWithSeparator)
1603 which escapes its arguments using `show`.
1604 """
1605 intercalate :: String -> [String] -> String
1606 intercalate separator strings = do
1607     l = length strings
1608     if l == 0
1609     then ""
1610     else if l == 1
1611     then strings!0
1612     else runProc do
1613         sb = StringBuilder.new
1614         sb << strings!0
1615         loop i | i == l = ()
1616                | otherwise = do
1617             sb << separator << strings!i
1618             loop (i+1)
1619         loop 1
1620         StringBuilder.toString sb
1621
1622 instance (Show a) => Show [a] where
1623     sb <+ l = do
1624         len = length l
1625         loop i = if i < len
1626                  then do
1627                      if (i>0) then sb << ", " else sb
1628                      sb <+ l!i
1629                      loop (i+1)
1630                  else sb << "]"
1631         sb << "["
1632         loop 0
1633
1634 importJava "java.util.List" where
1635     "`getList l i` returns the `i`th element of the list `l`. Indexing starts from zero. You can also use the `!` infix function for this purpose."
1636     @JavaName get
1637     getList :: [a] -> Integer -> a
1638
1639     @private
1640     @JavaName size
1641     lengthList :: [a] -> Integer
1642
1643     @private
1644     subList :: [a] -> Integer -> Integer -> [a]
1645
1646     @private
1647     isEmpty :: [a] -> Boolean
1648
1649 @private
1650 importJava "java.util.Collections" where
1651     emptyList :: [a]
1652     //singletonList :: a -> [a]
1653
1654 /*
1655 @inline
1656 emptyList :: [a]
1657 emptyList = build (\empty cons -> empty)
1658 */
1659
1660 "Creates a list with exectly one element."
1661 @inline
1662 singletonList :: a -> [a]
1663 singletonList v = build (\empty cons -> cons empty v)
1664
1665 /*
1666 // foldl f i (a + b) = foldl f (foldl f i a) b
1667
1668 appendList :: [a] -> [a] -> [a]
1669 appendList a b = build (\empty cons -> foldl cons (foldl cons empty a) b)
1670 */
1671
1672 importJava "org.simantics.scl.runtime.list.ShareableList" where
1673     "Concatenates two lists."
1674     @private
1675     @JavaName "concat"
1676     appendList :: [a] -> [a] -> [a]
1677
1678     "Adds the given value to the end of the list."
1679     @JavaName "add"
1680     addList :: [a] -> a -> [a]
1681
1682 @private
1683 importJava "java.util.ArrayList" where
1684     data ArrayList a
1685
1686     @JavaName "<init>"
1687     newArrayList :: <Proc> ArrayList a
1688
1689     @JavaName add
1690     addArrayList :: ArrayList a -> a -> <Proc> ()
1691
1692 """
1693 A primitive for constructing a list by `empty` and `cons` operations given to the function given as a parameter to this function.
1694 For example:
1695
1696     build (\empty cons -> cons (cons (cons empty 1) 2) 3)
1697
1698 produces
1699
1700     [1, 2, 3]
1701
1702 The SCL compiler makes the following optimization when encountering `build` and `foldl` functions after inlining:
1703
1704     foldl f i (build g) = g i f
1705 """
1706 @inline 2
1707 build :: forall b e2. (forall a e1. a -> (a -> b -> <e1> a) -> <e1,e2> a) -> <e2> [b]
1708 build f = runProc do
1709     l = newArrayList
1710     f () (\_ v -> addArrayList l v)
1711     Java.unsafeCoerce l
1712
1713 "A specific implementation of `map` for lists."
1714 @private
1715 @inline
1716 mapEList :: (a -> <e> b) -> [a] -> <e> [b]
1717 mapEList f l = build (\empty cons -> foldl (\cur x -> cons cur (f x)) empty l)
1718
1719 "A specific implementation of `fmap` for lists."
1720 @inline
1721 mapList :: (a -> b) -> [a] -> [b]
1722 mapList f l = build (\empty cons -> foldl (\cur x -> cons cur (f x)) empty l)
1723
1724 "`guardList v` returns a singleton `[()]` if `v=True` and the empty list if `v=False`."
1725 @inline
1726 guardList :: Boolean -> [()]
1727 guardList cond = build (\empty cons -> if cond then cons empty () else empty)
1728
1729 """
1730 `concatMap` combines `map` and `join` functions.
1731 It maps the elements of a given list to lists with the given function and concatenates the results.
1732
1733     concatMap f lst = join (map f lst) = [y | x <- lst, y <- f x]
1734 """
1735 @inline
1736 concatMap :: (a -> <e> [b]) -> [a] -> <e> [b]
1737 concatMap f l = build (\empty cons -> foldl (\cur le -> foldl cons cur (f le)) empty l)
1738
1739 """
1740 Applies the given function to the elements of the lists until the function returns something
1741 else than `Nothing`. This return value is also returned as a result of this function.
1742 """
1743 @inline
1744 mapFirst :: (a -> <e> Maybe b) -> [a] -> <e> Maybe b
1745 mapFirst f l = loop 0
1746   where
1747     len = length l
1748     loop i = if i == len
1749              then Nothing
1750              else match f (l!i) with
1751                  r @ (Just _) -> r
1752                  Nothing -> loop (i+1)
1753
1754 """
1755     foldl op initialValue list
1756
1757 applies a binary operator `op` to all elements of `list` from left to right
1758 starting with `initialValue`. For example,
1759
1760     foldl op init [x1, x2, x3, x4] = (((init `op` x1) `op` x2) `op` x3) `op` x4
1761 """
1762 @inline 2
1763 foldl :: forall a b e. (a -> b -> <e> a) -> a -> [b] -> <e> a
1764 foldl f initial l = loop initial 0
1765   where
1766     len = length l
1767     loop cur i = if i==len
1768                  then cur
1769                  else loop (f cur (l!i)) (i+1)
1770
1771 foldlI :: forall a b e. (Integer -> a -> b -> <e> a) -> a -> [b] -> <e> a
1772 foldlI f initial l = loop initial 0
1773   where
1774     len = length l
1775     loop cur i = if i==len
1776                  then cur
1777                  else loop (f i cur (l!i)) (i+1)
1778
1779 scanl :: (b -> a -> <e> b) -> b -> [a] -> <e> [b]
1780 scanl f initial l = build (\empty cons -> let
1781     len = length l
1782     loop cur i accum = let nl = cons accum cur
1783                            in if i==len
1784                            then nl
1785                             else loop (f cur (l!i)) (i+1) nl
1786   in loop initial 0 empty)
1787
1788 "`foldr` is defined like `foldl` but it process the list from right to left."
1789 @inline
1790 foldr :: (b -> a -> <e> a) -> a -> [b] -> <e> a
1791 foldr f initial l = loop initial (length l - 1)
1792   where
1793     loop cur i = if i < 0
1794                  then cur
1795                  else loop (f (l!i) cur) (i-1)
1796
1797 foldr1 :: (a -> a -> <e> a) -> [a] -> <e> a
1798 foldr1 f l = loop (l!(len-1)) (len-2)
1799   where
1800     len = length l
1801     loop cur i = if i < 0
1802                  then cur
1803                  else loop (f (l!i) cur) (i-1)
1804
1805 """
1806 `filter pred lst` returns those elements of `lst` that the predicate `pred` accepts. For example
1807
1808     filter (> 3) [1, 2, 3, 4, 5, 6] = [4, 5, 6]
1809 """
1810 @inline
1811 filter :: (a -> <e> Boolean) -> [a] -> <e> [a]
1812 filter p l = build (\empty cons -> foldl (\cur x -> if p x then cons cur x else cur) empty l)
1813
1814 """
1815 Takes those elements of the input list that match `(Just x)` and adds the contents to the resulting list. For example,
1816
1817     filterJust [Just 1, Nothing, Just 5] = [1, 5]
1818 """
1819 @inline
1820 filterJust :: [Maybe a] -> [a]
1821 filterJust l = build (\empty cons -> foldl (\cur x -> match x with Just v -> cons cur v ; _ -> cur) empty l)
1822
1823 listToMaybe :: [a] -> Maybe a
1824 listToMaybe l = if isEmpty l then Nothing else Just (l!0)
1825
1826 maybeToList :: Maybe a -> [a]
1827 maybeToList (Just a) = [a]
1828 maybeToList _ = []
1829
1830 """
1831 `takeWhile p l`, returns the longest prefix (possibly empty) of list `l` of elements that satisfy `p`
1832 """
1833 takeWhile :: (a -> <e> Boolean) -> [a] -> <e> [a]
1834 takeWhile f l = loop 0
1835   where
1836     len = length l
1837     loop i | i == len  = l
1838            | f (l!i)   = loop (i+1)
1839            | otherwise = take i l
1840
1841 partition :: (a -> <e> Boolean) -> [a] -> <e> ([a], [a])
1842 partition p l = runProc do
1843     res1 = newArrayList
1844     res2 = newArrayList
1845     for l (\el ->
1846         if p el
1847         then addArrayList res1 el
1848         else addArrayList res2 el
1849     )
1850     (Java.unsafeCoerce res1, Java.unsafeCoerce res2)
1851
1852 """
1853 `range begin end` produces a list of consecutive integers starting from `begin` and ending to `end` (including `end`).
1854 The compiler supports syntactic sugar `[begin..end]` for this function.
1855 """
1856 @inline
1857 range :: Integer -> Integer -> [Integer]
1858 range first last = build (\empty cons -> do
1859     loop i cur = if i > last then cur else loop (i+1) (cons cur i)
1860     loop first empty)
1861
1862 "A specific implementation of `iter` for lists."
1863 @inline
1864 iterList :: (a -> <e> b) -> [a] -> <e> ()
1865 iterList f l = foldl (\_ x -> ignore (f x)) () l
1866
1867 "A specific implementation of `iterI` for lists."
1868 @inline
1869 iterIList :: (Integer -> a -> <e> b) -> [a] -> <e> ()
1870 iterIList f l = do foldl (\i x -> do f i x ; i+1) 0 l ; ()
1871
1872 """
1873 Generates a list from a given starting state and iteration function.
1874 For example
1875
1876     let nextState 0 = Nothing
1877         nextState i = Just (i, i `div` 2)
1878     in  unfoldr nextState 30
1879
1880 produces
1881
1882     [30, 15, 7, 3, 1]
1883 """
1884 @inline
1885 unfoldr :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
1886 unfoldr f s = build (\empty cons -> do
1887     loop s cur =
1888         match f s with
1889             Just (el,newS) -> loop newS (cons cur el)
1890             _ -> cur
1891     loop s empty)
1892
1893 importJava "org.simantics.scl.runtime.Lists" where
1894     /*
1895     @private
1896     @JavaName map
1897     mapList :: (a -> b) -> [a] -> [b]
1898     @private
1899     @JavaName map
1900     mapEList :: (a -> <e> b) -> [a] -> <e> [b]
1901     @private
1902     @JavaName iter
1903     iterList :: (a -> <e> ()) -> [a] -> <e> ()
1904     concatMap :: (a -> <e> [b]) -> [a] -> <e> [b]
1905     */
1906     """
1907     Combines two lists into one list of pairs. The length of the resulting list is the length of the smallest input list.
1908
1909         zip [1, 2, 3, 4, 5] ['a', 'b', 'c'] = [(1, 'a'), (2, 'b'), (3, 'c')]
1910     """
1911     zip :: [a] -> [b] -> [(a,b)]
1912     "Combines two lists by using the given function for combining the elements. The length of the resulting list is the length of the smallest input list."
1913     zipWith :: (a -> b -> <e> c) -> [a] -> [b] -> <e> [c]
1914     """
1915     Produces two lists from one list of pairs.
1916
1917         unzip [(1, 'a'), (2, 'b'), (3, 'c')] = ([1, 2, 3], ['a', 'b', 'c'])
1918     """
1919     unzip :: [(a,b)] -> ([a],[b])
1920
1921     //"@filter p l@ returns those elements of @l@ that the predicate @p@ accepts."
1922     //filter :: (a -> <e> Boolean) -> [a] -> <e> [a]
1923     //filterJust :: [Maybe a] -> [a]
1924     /*
1925     foldl :: (a -> b -> <e> a) -> a -> [b] -> <e> a
1926     */
1927     "Like `foldl` but assumes that the list is non-empty so the initial is not needed."
1928     foldl1 :: (a -> a -> <e> a) -> [a] -> <e> a
1929     //unfoldr :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
1930
1931     "Sorts the list using the given comparator."
1932     sortWith :: (a -> a -> <e> Integer) -> [a] -> <e> [a]
1933
1934     """
1935     Given a list of key-value pairs, the function produces a function that finds a value
1936     efficiently for the given key.
1937     """
1938     index :: [(a,b)] -> a -> Maybe b
1939
1940     """
1941     Given a list of values and a function computing a key for each value, the function produces a function that finds a value
1942     effeciently for the given key.
1943     """
1944     indexBy ::  (a -> b) -> [a] -> b -> Maybe a
1945
1946     "Works like `index` but uses the given functions as hash codes and equality."
1947     indexWith :: (a -> Integer) -> (a -> a -> Boolean) -> [(a,b)] -> a -> Maybe b
1948
1949     "Groups a list values by a key computed by the given function."
1950     groupBy :: (a -> <e> b) -> [a] -> <e> [(b, [a])]
1951
1952     "Groups a list of key-value pairs by the keys."
1953     group :: [(a,b)] -> [(a, [b])]
1954
1955     "Composition of index and groupBy."
1956     indexGroupBy :: (a -> <e> b) -> [a] -> <e> (b -> [a])
1957
1958     "Composition of index and group."
1959     indexGroup :: [(a,b)] -> a -> [b]
1960
1961     groupWith :: (b -> Integer) -> (b -> b -> Boolean) -> (a -> <e> b) -> (a -> <e> c) -> [a] -> <e> [(b, [c])]
1962
1963     "Removes duplicates (all but the first occurrence) from the list but otherwise preserves the order of the elements."
1964     unique :: [a] -> [a]
1965
1966     "Like `unique`, but uses the given function for finding the key values used for uniqueness testing."
1967     uniqueBy :: (a -> b) -> [a] -> [a]
1968
1969     "Works like `unique` but uses the given function for equality tests."
1970     uniqueWith :: (a -> a -> Boolean) -> [a] -> [a]
1971
1972     "Works like `\\\\` but uses the given function for equality tests."
1973     deleteAllBy :: (a -> a -> Boolean) -> [a] -> [a] -> [a]
1974
1975     @private
1976     listDifference :: [a] -> [a] -> [a]
1977
1978     //range :: Integer -> Integer -> [Integer]
1979
1980     //build :: (forall a. a -> (a -> b -> <e> a) -> <e> a) -> <e> [b]
1981
1982 "`elem el lst` return true, if `el` occurs in the list `lst`."
1983 elem :: a -> [a] -> Boolean
1984 elem el l = loop 0
1985   where
1986     len = length l
1987     loop i | i < len = if el == l!i
1988                        then True
1989                        else loop (i+1)
1990            | otherwise = False
1991
1992 "`elemMaybe v1 (Just v2)` returns true if `v1 == v2`. `elemMaybe v1 Nothing` is always false."
1993 elemMaybe :: a -> Maybe a -> Boolean
1994 elemMaybe el m = match m with
1995     Just el2 -> el == el2
1996     Nothing -> False
1997
1998 """
1999 Computes a list that contains only elements that belongs to both input lists.
2000 """
2001 intersect :: [a] -> [a] -> [a]
2002 intersect a b = filter f a
2003   where
2004     f e = elem e b
2005
2006 "Reverses a given list. For example, `reverse [1,2,3] = [3,2,1]`"
2007 reverse :: [a] -> [a]
2008 reverse l = [l!(len-i) | i <- [1..len]]
2009   where
2010     len = length l
2011
2012 """
2013 Transposes the rows and columns of its argument. For example,
2014
2015     transpose [[1,2,3],[4,5,6]] == [[1,4],[2,5],[3,6]]
2016     transpose [[1,2],[3,4,5]] == [[1,3],[2,4],[5]]
2017 """
2018 transpose xss = [[xs!i | xs <- xss, i < length xs]
2019                 | i <- [0..maximum [length xs | xs <- xss]-1]]
2020
2021 "Works like `unfoldr` but generates the list from right to left."
2022 unfoldl :: (b -> <e> Maybe (a, b)) -> b -> <e> [a]
2023 unfoldl f seed = reverse $ unfoldr f seed
2024
2025 "Removes the first element of the list, if the list is non-empty."
2026 tail :: [a] -> [a]
2027 tail l = if len < 2 then emptyList else subList l 1 len
2028   where
2029     len = length l
2030
2031 "Tries to find the given key from the list of key-value pairs and returns the corresponding value."
2032 lookup ::  a -> [(a, b)] -> Maybe b
2033 lookup el l = do
2034     len = length l
2035     loop i = if i < len
2036              then match l!i with
2037                (a,b) | a == el   -> Just b
2038                      | otherwise -> loop (i+1)
2039              else Nothing
2040     loop 0
2041
2042 "Conjunction over a list."
2043 @inline
2044 and :: [Boolean] -> Boolean
2045 and = foldl (&&) True
2046
2047 "Disjunction over a list."
2048 @inline
2049 or :: [Boolean] -> Boolean
2050 or  = foldl (||) False
2051
2052 """
2053 `any pred lst` tests whether the predicate `pred` holds some element of `lst`.
2054 It returns immediately when it encounters the first value satisfying the predicate.
2055 """
2056 any :: (a -> <e> Boolean) -> [a] -> <e> Boolean
2057 any p =  or . map p
2058
2059 """
2060 `all pred lst` tests whether the predicate `pred` holds for all elements of `lst`.
2061 It returns immediately when it encounters the first value not satisfying the predicate.
2062 """
2063 all :: (a -> <e> Boolean) -> [a] -> <e> Boolean
2064 all p =  and . map p
2065
2066 """
2067 Returns the first element of the list satisfying the given condition,
2068 or `Nothing` if there is no such element.
2069 """
2070 findFirst :: (a -> <e> Boolean) -> [a] -> <e> Maybe a
2071 findFirst p l = loop 0
2072   where
2073     len = length l
2074     loop i = if i < len
2075              then let el = l!i in
2076                   if p el
2077                   then Just el
2078                   else loop (i+1)
2079              else Nothing
2080     loop 0
2081
2082
2083 """
2084 Sorts the given list using its default order.
2085 """
2086 @inline
2087 sort :: Ord a => [a] -> [a]
2088 sort = sortWith compare
2089
2090 """
2091 Sorts the lists by the values computed by the first function.
2092 For example
2093
2094     sortBy snd [(1,5), (2,3), (3,4)] = [(2,3), (3,4), (1,5)]
2095 """
2096 @inline
2097 sortBy :: Ord b => (a -> <e> b) -> [a] -> <e> [a]
2098 sortBy f l = sortWith (\x y -> compare (f x) (f y)) l
2099 // This is faster if f is slow, but will generate more auxiliary structures
2100 //sortBy f l = map snd (sortWith (\(x,_) (y,_) -> compare x y) [(f x, x) | x <- l])
2101
2102 "`a \\\\ b` removes all elements of `b` from the list `a`."
2103 (\\) :: [a] -> [a] -> [a]
2104 (\\) = listDifference
2105
2106 /// Dynamic ///
2107
2108 importJava "java.lang.Object" where
2109     "A data type that can represent any value."
2110     data Dynamic
2111
2112     @private
2113     @JavaName toString
2114     showDynamic :: Dynamic -> String
2115
2116 instance Show Dynamic where
2117     show = showDynamic
2118
2119 "Converts a value to `Dynamic` type."
2120 toDynamic :: a -> Dynamic
2121 toDynamic = Java.unsafeCoerce
2122
2123 "Converts a `Dynamic` value to a required value, or fails if the conversion is not possible."
2124 importJava "org.simantics.scl.compiler.runtime.ValueConversion" where
2125     fromDynamic :: Typeable a => Dynamic -> a
2126
2127 /// Procedures ///
2128
2129 importJava "org.simantics.scl.runtime.procedure.Ref" where
2130     "A mutable reference to a value of type `a`."
2131     data Ref a
2132
2133     "Creates a new reference with the given initial value."
2134     @JavaName "<init>"
2135     ref :: a -> <Proc> (Ref a)
2136
2137     "Returns the current value of the reference."
2138     @JavaName "value"
2139     getRef :: Ref a -> <Proc> a
2140
2141     "Sets a new value for the reference."
2142     @JavaName "<set>value"
2143     (:=) :: Ref a -> a -> <Proc> ()
2144
2145 instance Show (Ref a) where
2146     show _ = "<reference>"
2147
2148 importJava "org.simantics.scl.runtime.reporting.SCLReporting" where
2149     "Prints the given string to the console."
2150     @JavaName "print"
2151     printString :: String -> <Proc> ()
2152     "Prints an error message to the console."
2153     printError :: String -> <Proc> ()
2154     "Reports that certain amount of work has been done for the current task."
2155     didWork :: Double -> <Proc> ()
2156     """
2157     `printingToFile "fileName" expression` executes the `expression` so that all its console prints
2158     are written to the file given as a first parameter.
2159     """
2160     printingToFile :: String -> (<e> a) -> <e> a
2161     """
2162     `printErrorsAsNormalPrints expression` executes the `expression` so that all its error prints
2163     are printed as normal prints. This is useful mainly in testing scripts for checking that the implementations
2164     give proper error messages with invalid inputs.
2165     """
2166     printErrorsAsNormalPrints :: (<e> a) -> <e> a
2167     """
2168     `disablePrintingForCommand expression` executes the `expression` so that it does not print return values.
2169     Errors are printed normally.
2170     """
2171     disablePrintingForCommand :: (<e> a) -> <e> a
2172
2173
2174 importJava "org.simantics.scl.runtime.procedure.Procedures" where
2175     "Returns `True` if the current thread has been interrupted."
2176     isInterrupted :: <Proc> Boolean
2177     "Checks whether the current thread has been interrupted and throws an exception if it is."
2178     checkInterrupted :: <Proc> ()
2179     "Generates a random identifier."
2180     generateUID :: <Proc> String
2181
2182     "Executes the given expression and catches certain class of exceptions (specified by the catch handler that is given as a second parameter.)"
2183     @JavaName catch_
2184     catch :: VecComp ex => (<e,Exception> a) -> (ex -> <e> a) -> <e> a
2185
2186 importJava "java.lang.Throwable" where
2187     data Throwable
2188     @private
2189     @JavaName toString
2190     showThrowable :: Throwable -> String
2191 importJava "java.lang.Exception" where
2192     data Exception
2193     @private
2194     @JavaName toString
2195     showException :: Exception -> String
2196
2197 instance Show Throwable where
2198     show = showThrowable
2199 instance Show Exception where
2200     show = showException
2201
2202 "Prints the given value in the console."
2203 @inline
2204 print :: Show a => a -> <Proc> ()
2205 print v = printString (showForPrinting v)
2206 /*
2207 instance Show TypeRep where
2208     sb <+ (TApply (TCon "Builtin" "[]") b) =
2209         sb << "[" <+ b << "]"
2210     sb <+ (TApply (TApply (TCon "Builtin" "(,)") c1) c2) =
2211         sb << "(" <+ c1 << "," <+ c2 << ")"
2212     sb <+ (TApply (TApply (TApply (TCon "Builtin" "(,,)") c1) c2) c3) =
2213         sb << "(" <+ c1 << "," <+ c2 << "," <+ c3 << ")"
2214     sb <+ (TApply (TApply (TApply (TApply (TCon "Builtin" "(,,,)") c1) c2) c3) c4) =
2215         sb << "(" <+ c1 << "," <+ c2 << "," <+ c3 << "," <+ c4 << ")"
2216
2217     sb <+ (TCon _ name) = sb << name
2218     sb <+ (TApply a b) = sb <+ Par 1 a << " " <+ Par 2 b
2219     sb <+ (TFun a b) = sb <+ Par 1 a << " -> " <+ b
2220
2221     precedence (TCon _ _) = 0
2222     precedence (TFun _ _) = 2
2223     precedence (TApply a _) = if isSpecialType a then 0 else 1
2224       where
2225         isSpecialType (TCon "Builtin" "[]") = True
2226         isSpecialType (TCon "Builtin" "()") = True
2227         isSpecialType (TCon "Builtin" "(,)") = True
2228         isSpecialType (TCon "Builtin" "(,,)") = True
2229         isSpecialType (TCon "Builtin" "(,,,)") = True
2230         isSpecialType (TApply a _) = isSpecialType a
2231 */
2232
2233 // ByteArray
2234
2235 importJava "java.util.Arrays" where
2236     @private
2237     @JavaName toString
2238     byteArrayToString :: ByteArray -> String
2239
2240 instance Show ByteArray where
2241     show = byteArrayToString
2242
2243 // Type
2244
2245 @private
2246 importJava "org.simantics.scl.compiler.types.Type" where
2247     @JavaName toString
2248     showType :: Type -> String
2249
2250 importJava "org.simantics.scl.compiler.types.Types" where
2251     removeForAll :: Type -> Type
2252
2253 instance Show Type where
2254     show = showType