import "JavaBuiltin" as Java

importJava "java.util.Iterator" where
    data T a
    
    hasNext :: T a -> <Proc> Boolean
    next :: T a -> <Proc> a
    remove :: T a -> <Proc> ()

@inline
iter :: (a -> <e> b) -> T a -> <Proc,e> ()
iter f it = loop ()
  where
    loop _ = 
        if hasNext it
        then do
            f (next it)
            loop ()
        else ()

@inline
iterI :: (Integer -> a -> <e> b) -> T a -> <Proc,e> ()
iterI f it = loop 0
  where
    loop i = 
        if hasNext it
        then do
            f i (next it)
            loop (Java.iadd i 1)
        else ()
        
@inline
iterB :: (a -> <e> Boolean) -> T a -> <Proc,e> Boolean
iterB f it = loop ()
  where
    loop _ = 
        if hasNext it 
        then if f (next it)
             then loop ()
             else False
        else True

@inline
filter :: (a -> <e> Boolean) -> T a -> <Proc,e> ()
filter f it = loop ()
  where
    loop _ = 
        if hasNext it
        then do
            if f (next it)
            then ()
            else remove it
            loop ()
        else ()

@inline
mapFirst :: (a -> <e> Maybe b) -> T a -> <Proc,e> Maybe b
mapFirst f it = loop ()
  where
    loop _ = 
        if hasNext it 
        then match f (next it) with
                 Nothing -> loop ()
                 r -> r
        else Nothing

@inline
fold :: (a -> b -> <e> a) -> a -> T b -> <Proc,e> a
fold f init it = loop init
  where
    loop cur =
        if hasNext it
        then loop (f cur (next it))
        else cur

importJava "java.lang.Iterable" where
    data Iterable a
    
    iterator :: Iterable a -> <Proc> T a